media-libs/libfreehand: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 62 insertions, 59 deletions

diff --git a/media-libs/libfreehand/libfreehand-0.1.2-r1.ebuild b/media-libs/libfreehand/libfreehand-0.1.2-r1.ebuild
new file mode 100644
index 000000000000..c1338ae71215
--- /dev/null
+++ b/media-libs/libfreehand/libfreehand-0.1.2-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libfreehand.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://dev-www.libreoffice.org/src/libfreehand/${P}.tar.xz"
+	KEYWORDS="amd64 ~arm arm64 ~hppa ppc ppc64 ~riscv ~sparc x86"
+fi
+
+DESCRIPTION="Library for import of FreeHand drawings"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libfreehand"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/librevenge
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-libs/icu
+	dev-util/gperf
+	media-libs/lcms
+	sys-devel/libtool
+	test? ( dev-util/cppunit )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+PATCHES=( "${FILESDIR}"/${P}-icu-65.patch )
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == *9999 ]]; then
+		mkdir -p m4 || die
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable test tests)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -type f -delete || die
+}
diff --git a/media-libs/libfreehand/libfreehand-0.1.2.ebuild b/media-libs/libfreehand/libfreehand-0.1.2.ebuild
deleted file mode 100644
index 582c605fe52b..000000000000
--- a/media-libs/libfreehand/libfreehand-0.1.2.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit flag-o-matic
-
-EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libfreehand.git"
-[[ ${PV} == 9999 ]] && inherit autotools git-r3
-
-DESCRIPTION="Library for import of FreeHand drawings"
-HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libfreehand"
-[[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libfreehand/${P}.tar.xz"
-
-LICENSE="MPL-2.0"
-SLOT="0"
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="amd64 ~arm arm64 ~hppa ppc ppc64 ~riscv ~sparc x86"
-IUSE="doc static-libs test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-libs/librevenge
-	sys-libs/zlib
-"
-DEPEND="${RDEPEND}
-	dev-libs/boost
-	dev-libs/icu
-	dev-util/gperf
-	media-libs/lcms
-	sys-devel/libtool
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen )
-	test? ( dev-util/cppunit )
-"
-
-PATCHES=( "${FILESDIR}/${P}-icu-65.patch" )
-
-src_prepare() {
-	default
-	[[ -d m4 ]] || mkdir "m4"
-	[[ ${PV} == 9999 ]] && eautoreconf
-}
-
-src_configure() {
-	# bug 619762
-	append-cxxflags -std=c++14
-
-	econf \
-		--disable-werror \
-		$(use_with doc docs) \
-		$(use_enable static-libs static) \
-		$(use_enable test tests)
-}
-
-src_install() {
-	default
-	find "${D}" -name '*.la' -delete || die
-}