media-libs/libopenraw: version bump 0.1.0

Gentoo-bug: 601240

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 60 insertions, 0 deletions

diff --git a/media-libs/libopenraw/libopenraw-0.1.0.ebuild b/media-libs/libopenraw/libopenraw-0.1.0.ebuild
new file mode 100644
index 000000000000..29ddc8b3a642
--- /dev/null
+++ b/media-libs/libopenraw/libopenraw-0.1.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils gnome2-utils
+
+DESCRIPTION="A decoding library for RAW image formats"
+HOMEPAGE="https://libopenraw.freedesktop.org/wiki/"
+SRC_URI="https://${PN}.freedesktop.org/download/${P}.tar.bz2"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0/7"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-solaris"
+IUSE="gtk static-libs test"
+
+RDEPEND="
+	dev-libs/libxml2
+	virtual/jpeg:0
+	gtk? (
+		dev-libs/glib:2
+		>=x11-libs/gdk-pixbuf-2.24.0:2
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-libs/boost-1.35
+	virtual/pkgconfig
+	test? ( net-misc/curl )
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README TODO )
+
+src_prepare() {
+	has_version '>=media-libs/jpeg-9a:0' && epatch "${FILESDIR}"/${P}-jpeg-9a.patch
+	default
+}
+
+src_configure() {
+	econf \
+		--with-boost="${EPREFIX}"/usr \
+		$(use_enable static-libs static) \
+		$(use_enable gtk gnome)
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
+
+pkg_preinst() {
+	use gtk && gnome2_gdk_pixbuf_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_gdk_pixbuf_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_gdk_pixbuf_update
+}