media-libs/lvtk: py3 + fixed homepage

Closes: https://bugs.gentoo.org/735384
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

1 files changed, 66 insertions, 0 deletions

diff --git a/media-libs/lvtk/lvtk-1.2.0-r1.ebuild b/media-libs/lvtk/lvtk-1.2.0-r1.ebuild
new file mode 100644
index 000000000000..c183d2993495
--- /dev/null
+++ b/media-libs/lvtk/lvtk-1.2.0-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit python-single-r1 waf-utils
+
+WAF_VER=2.0.20
+
+DESCRIPTION="A set of C++ wrappers around the LV2 C API"
+HOMEPAGE="https://lvtk.org/"
+SRC_URI="https://github.com/lvtk/lvtk/archive/${PV}.tar.gz -> ${P}.tar.gz
+	https://waf.io/waf-2.0.20"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc examples +gtk2 +tools"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="media-libs/lv2
+	>=dev-libs/boost-1.40.0
+	${PYTHON_DEPS}
+	gtk2? ( dev-cpp/gtkmm:2.4 )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen
+		media-gfx/graphviz )
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-boost-system-underlinking.patch"
+	"${FILESDIR}/${P}-py3.patch"
+)
+
+src_unpack() {
+	unpack ${P}.tar.gz || die
+
+	# we need newer version of waf to work with py3
+	cp "${DISTDIR}/waf-${WAF_VER}" "${S}/waf" || die
+}
+
+src_configure() {
+	local mywafconfargs=(
+		"--docdir=${EPREFIX}/usr/share/doc/${PF}"
+		"--lv2dir=${EPREFIX}/usr/$(get_libdir)/lv2"
+	)
+	use debug    && mywafconfargs+=( "--debug" )
+	use doc      && mywafconfargs+=( "--docs" )
+	use examples || mywafconfargs+=( "--disable-examples" )
+	use tools    || mywafconfargs+=( "--disable-tools" )
+	use gtk2     || mywafconfargs+=( "--disable-ui" )
+	waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+src_install() {
+	waf-utils_src_install
+
+	# It does not respect docdir properly, reported upstream
+	if use doc; then
+		mv "${ED}/usr/share/doc/${PF}/lvtk-1/html" "${ED}/usr/share/doc/${PF}/html" || die
+		rmdir "${ED}/usr/share/doc/${PF}/lvtk-1" || die
+	fi
+}