media-libs/osl: Version bump to 1.10.13

This version works with openimageio 2 (fixes build failure of 1.10.10)

Add support for LLVM 10, which requires C++14

Enable shared libraries
Add github page as second homepage

Added subslot operator otherwise upgrading to 1.11 will leave behind
preserved libraries (blender is the only current client in the tree)

Thanks to Mehw, Cyrillic, Peter Karlsson, Reggie, Luke A Guest, and
Joonas Niilola for their contributions to the bugs mentioned below
which forms the bulk of this update.

Signed-off-by: Adrian Grigo <agrigo2001@yahoo.com.au>
Closes: https://bugs.gentoo.org/735750
Closes: https://bugs.gentoo.org/751580
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 87 insertions, 0 deletions

diff --git a/media-libs/osl/osl-1.10.13.ebuild b/media-libs/osl/osl-1.10.13.ebuild
new file mode 100644
index 000000000000..85fdd979a7fe
--- /dev/null
+++ b/media-libs/osl/osl-1.10.13.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit cmake llvm toolchain-funcs
+
+# check this on updates
+LLVM_MAX_SLOT=10
+
+DESCRIPTION="Advanced shading language for production GI renderers"
+HOMEPAGE="http://opensource.imageworks.com/?p=osl https://github.com/imageworks/OpenShadingLanguage"
+SRC_URI="https://github.com/imageworks/OpenShadingLanguage/archive/Release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/10"
+KEYWORDS="~amd64 ~x86"
+
+X86_CPU_FEATURES=(
+	sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="doc partio qt5 test ${CPU_FEATURES[@]%:*}"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/pugixml
+	media-libs/openexr:=
+	media-libs/openimageio:=
+	<sys-devel/clang-11:=
+	sys-libs/zlib
+	partio? ( media-libs/partio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.10.5-fix-install-shaders.patch"
+)
+
+# Restricting tests as Make file handles them differently
+RESTRICT="test"
+
+S="${WORKDIR}/OpenShadingLanguage-Release-${PV}"
+
+llvm_check_deps() {
+	has_version -r "sys-devel/clang:${LLVM_SLOT}"
+}
+
+src_configure() {
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd} ]] && mysimd=("0")
+
+	local gcc=$(tc-getCC)
+	# LLVM needs CPP11. Do not disable.
+	local mycmakeargs=(
+		-DCMAKE_CXX_STANDARD=14
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DENABLERTTI=OFF
+		-DINSTALL_DOCS=$(usex doc)
+		-DLLVM_STATIC=OFF
+		-DOSL_BUILD_TESTS=$(usex test)
+		-DSTOP_ON_WARNING=OFF
+		-DUSE_PARTIO=$(usex partio)
+		-DUSE_QT=$(usex qt5)
+		-DUSE_SIMD="$(IFS=","; echo "${mysimd[*]}")"
+	)
+
+	cmake_src_configure
+}