media-libs/rubberband: bump to 1.9.0

1) added use flags for optional features
2) organized deps

Closes: https://bugs.gentoo.org/547904
Closes: https://bugs.gentoo.org/685110
Closes: https://bugs.gentoo.org/590500
Package-Manager: Portage-3.0.7, Repoman-3.0.1
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

1 files changed, 67 insertions, 0 deletions

diff --git a/media-libs/rubberband/rubberband-1.9.0.ebuild b/media-libs/rubberband/rubberband-1.9.0.ebuild
new file mode 100644
index 000000000000..40bdbdaeeb76
--- /dev/null
+++ b/media-libs/rubberband/rubberband-1.9.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="An audio time-stretching and pitch-shifting library and utility program"
+HOMEPAGE="https://www.breakfastquay.com/rubberband/"
+SRC_URI="https://breakfastquay.com/files/releases/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="ladspa static-libs +programs vamp"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+CDEPEND="
+	media-libs/libsamplerate[${MULTILIB_USEDEP}]
+	media-libs/libsndfile
+	sci-libs/fftw:3.0[${MULTILIB_USEDEP}]
+	ladspa? ( media-libs/ladspa-sdk )
+	vamp? ( media-libs/vamp-plugin-sdk[${MULTILIB_USEDEP}] )
+"
+RDEPEND="${CDEPEND}"
+DEPEND="${CDEPEND}"
+
+src_prepare() {
+	default
+	if ! use static-libs ; then
+		sed -e '/^all:/s/$(STATIC_TARGET)//' \
+			-e '/^\tcp $(STATIC_TARGET)/d' \
+			-i Makefile.in || die
+	fi
+
+	sed -e '/cp -f.*JNI_TARGET/d' -i Makefile.in || die
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf WITH_PROGRAMS=$(usex programs) WITH_LADSPA=$(usex ladspa) WITH_VAMP=$(usex vamp)
+}
+
+multilib_src_compile() {
+	emake WITH_PROGRAMS=$(usex programs) WITH_LADSPA=$(usex ladspa) WITH_VAMP=$(usex vamp)
+}
+
+multilib_src_install() {
+	# fix libdir in .pc file
+	sed -iE "s%/lib$%/$(get_libdir)%g" "${BUILD_DIR}/rubberband.pc.in" || die "Failed to fix .pc file"
+
+	emake INSTALL_BINDIR="${ED}/usr/bin" \
+		INSTALL_INCDIR="${ED}/usr/include/rubberband" \
+		INSTALL_LIBDIR="${ED}/usr/$(get_libdir)" \
+		INSTALL_VAMPDIR="${ED}/usr/$(get_libdir)/vamp" \
+		INSTALL_LADSPADIR="${ED}/usr/$(get_libdir)/ladspa" \
+		INSTALL_LRDFDIR="${ED}/usr/share/ladspa/rdf" \
+		INSTALL_PKGDIR="${ED}/usr/$(get_libdir)/pkgconfig" \
+		install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+}