media-libs/sratom: bump to 0.6.8

Bug: https://bugs.gentoo.org/724668
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/media-libs/sratom/sratom-0.6.8.ebuild b/media-libs/sratom/sratom-0.6.8.ebuild
new file mode 100644
index 000000000000..b3294902ca69
--- /dev/null
+++ b/media-libs/sratom/sratom-0.6.8.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+PYTHON_REQ_USE='threads(+)'
+inherit python-any-r1 waf-utils multilib-build multilib-minimal
+
+DESCRIPTION="Library for serialising LV2 atoms to/from RDF, particularly the Turtle syntax"
+HOMEPAGE="http://drobilla.net/software/sratom/"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	dev-libs/serd
+	dev-libs/sord
+	media-libs/lv2
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+"
+DOCS=( "NEWS" "README.md" )
+
+src_prepare() {
+	sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		--docdir=/usr/share/doc/${PF} \
+		$(multilib_native_usex doc --docs "") \
+		$(usex test --test "") \
+		$(usex static-libs --static "")
+}
+
+multilib_src_test() {
+	./waf test || die
+}
+
+multilib_src_compile() {
+	waf-utils_src_compile
+	default
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+	default
+}