media-libs/vulkan-layers: Fix eclass

Closes: https://bugs.gentoo.org/822249
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

2 files changed, 61 insertions, 7 deletions

diff --git a/media-libs/vulkan-layers/vulkan-layers-1.2.189-r1.ebuild b/media-libs/vulkan-layers/vulkan-layers-1.2.189-r1.ebuild
new file mode 100644
index 000000000000..3e0893062695
--- /dev/null
+++ b/media-libs/vulkan-layers/vulkan-layers-1.2.189-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-ValidationLayers
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{8,9} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-${PV}
+fi
+
+DESCRIPTION="Vulkan Validation Layers"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="wayland X"
+
+BDEPEND=">=dev-util/cmake-3.10.2"
+RDEPEND=">=dev-util/spirv-tools-20210825:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-cpp/robin-hood-hashing
+	>=dev-util/glslang-11.6.0:=[${MULTILIB_USEDEP}]
+	>=dev-util/vulkan-headers-${PV}
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+                -DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_LAYER_SUPPORT_FILES=ON
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DBUILD_TESTS=OFF
+		-DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
+		-DCMAKE_INSTALL_INCLUDEDIR="${EPREFIX}/usr/include/vulkan/"
+		-DSPIRV_HEADERS_INSTALL_DIR="${ESYSROOT}/usr/include/spirv"
+	)
+	cmake_src_configure
+}
diff --git a/media-libs/vulkan-layers/vulkan-layers-9999.ebuild b/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
index f53561f9c1fe..3e0893062695 100644
--- a/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
+++ b/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
@@ -4,8 +4,7 @@
 EAPI=7
 
 MY_PN=Vulkan-ValidationLayers
-CMAKE_ECLASS="cmake-utils"
-CMAKE_MAKEFILE_GENERATOR="emake"
+CMAKE_ECLASS="cmake"
 PYTHON_COMPAT=( python3_{8,9} )
 inherit cmake-multilib python-any-r1
 
@@ -40,12 +39,10 @@ DEPEND="${RDEPEND}
 	)
 "
 
-src_prepare() {
-	cmake-utils_src_prepare
-}
-
 multilib_src_configure() {
 	local mycmakeargs=(
+                -DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
 		-DCMAKE_SKIP_RPATH=ON
 		-DBUILD_LAYER_SUPPORT_FILES=ON
 		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
@@ -56,5 +53,5 @@ multilib_src_configure() {
 		-DCMAKE_INSTALL_INCLUDEDIR="${EPREFIX}/usr/include/vulkan/"
 		-DSPIRV_HEADERS_INSTALL_DIR="${ESYSROOT}/usr/include/spirv"
 	)
-	cmake-utils_src_configure
+	cmake_src_configure
 }