media-libs/vulkan-loader: add 1.3.275

Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

3 files changed, 60 insertions, 1 deletions

diff --git a/media-libs/vulkan-loader/Manifest b/media-libs/vulkan-loader/Manifest
index 1ffeba88fa6f..88ffecefba72 100644
--- a/media-libs/vulkan-loader/Manifest
+++ b/media-libs/vulkan-loader/Manifest
@@ -1,2 +1,3 @@
 DIST vulkan-loader-1.3.261.tar.gz 1684713 BLAKE2B 0321a56329cc8f578e07c24a53846f0a3ac9f81ce897975f0d0732db6a6ab905e682a81cb232d96d01311a9d9b89fb142b3c0eca5330371f42ba52e12c7ed2cc SHA512 f43bf9714c30b0751d9f6725ad7df7f70516b5e12a637bfb4cdf175b33d2be78e1717a3ae9537544ca84e0c89d5b759d537b932eec7f5502fcc871f6cdaa440c
 DIST vulkan-loader-1.3.268.tar.gz 1689273 BLAKE2B 6d7c1bfe82f594a68f3298d884efb61556b6d408357eb0360db2103af17bd47f981916dcc7584f8380c2530a88f05d59faa0754993975219e1955941dd3d32d8 SHA512 01e5f281efd5702b9930cecf3148aad9a79812c54e780a5a8ff2df2326ae10511001f1b6e3ebde19e47de229a9c97f6195b6b1e9fb7b3b4c88a4d1b6746f7aea
+DIST vulkan-loader-1.3.275.tar.gz 1701415 BLAKE2B c92cc2d3ff3c90eaaa820f0f857030ab6f957d0691f7cbaf53985bd4d4c6f0f2b4222623740bd2c433c2e0116545af37b8ac9959b554b800ca95a978fd1b14b5 SHA512 7af0110083ab827e4ea8b4ea3e3ce00d9387f27f5725cefd426fa4dee4b80bc83210248c2968577a90bb82de8efb1a68691a1bdb93769f2f04600c5a3d3eff91
diff --git a/media-libs/vulkan-loader/vulkan-loader-1.3.275.ebuild b/media-libs/vulkan-loader/vulkan-loader-1.3.275.ebuild
new file mode 100644
index 000000000000..ca20e66ef4a1
--- /dev/null
+++ b/media-libs/vulkan-loader/vulkan-loader-1.3.275.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=Vulkan-Loader
+inherit flag-o-matic cmake-multilib toolchain-funcs
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/vulkan-sdk-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-vulkan-sdk-${PV}
+fi
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="layers wayland X"
+
+DEPEND="
+	~dev-util/vulkan-headers-${PV}
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+PDEPEND="layers? ( media-libs/vulkan-layers:=[${MULTILIB_USEDEP}] )"
+
+multilib_src_configure() {
+	# Integrated clang assembler doesn't work with x86 - Bug #698164
+	if tc-is-clang && [[ ${ABI} == x86 ]]; then
+		append-cflags -fno-integrated-as
+	fi
+
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_TESTS=OFF
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	keepdir /etc/vulkan/icd.d
+
+	cmake_src_install
+}
diff --git a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
index 8cc74ccb97e7..7d311b4ae225 100644
--- a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
+++ b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
@@ -49,7 +49,6 @@ multilib_src_configure() {
 		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
 		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
 		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
-		-DENABLE_WERROR=OFF
 	)
 	cmake_src_configure
 }