media-sound/cava: add 0.8.2

This version removes the need for xxd/vim-core. Also no
longer segfault if no audio backends, so remove the warning.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 64 insertions, 0 deletions

diff --git a/media-sound/cava/cava-0.8.2.ebuild b/media-sound/cava/cava-0.8.2.ebuild
new file mode 100644
index 000000000000..7afa4ce04e09
--- /dev/null
+++ b/media-sound/cava/cava-0.8.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Console-based Audio Visualizer for Alsa"
+HOMEPAGE="https://github.com/karlstav/cava/"
+SRC_URI="https://github.com/karlstav/cava/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa +ncurses portaudio pulseaudio sdl sndio"
+
+RDEPEND="
+	dev-libs/iniparser:4
+	sci-libs/fftw:=
+	alsa? ( media-libs/alsa-lib )
+	ncurses? ( sys-libs/ncurses:= )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl2[opengl,video] )
+	sndio? ( media-sound/sndio:= )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.8.0-gentoo-iniparser4.patch
+)
+
+src_prepare() {
+	default
+
+	# https://github.com/karlstav/cava/issues/450
+	sed -i 's/-Werror //' Makefile.am || die
+
+	echo ${PV} > version || die
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_enable alsa input-alsa)
+		$(use_enable portaudio input-portaudio)
+		$(use_enable pulseaudio input-pulse)
+		$(use_enable sndio input-sndio)
+
+		$(use_enable ncurses output-ncurses)
+		$(use_enable sdl output-sdl)
+
+		GENTOO_SYSROOT="${ESYSROOT}" # see iniparser4.patch
+	)
+
+	econf "${econfargs[@]}"
+}
+
+pkg_postinst() {
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		elog "A default ~/.config/cava/config will be created after initial"
+		elog "use of ${PN}, see it and ${EROOT}/usr/share/doc/${PF}/README*"
+		elog "for configuring audio input and more."
+	fi
+}