media-sound/jack_capture: fix RDEPEND typo

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/media-sound/jack_capture/jack_capture-0.9.73-r1.ebuild b/media-sound/jack_capture/jack_capture-0.9.73-r1.ebuild
new file mode 100644
index 000000000000..17e85197eb3d
--- /dev/null
+++ b/media-sound/jack_capture/jack_capture-0.9.73-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="JACK Recording utility"
+HOMEPAGE="https://github.com/kmatheussen/jack_capture"
+SRC_URI="https://github.com/kmatheussen/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="mp3 ogg osc"
+
+RDEPEND="
+	media-libs/libsndfile
+	virtual/jack
+	mp3? ( media-sound/lame )
+	ogg? ( media-libs/libogg )
+	osc? ( media-libs/liblo )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-Makefile.patch
+)
+
+DOCS=( README config )
+
+src_prepare() {
+	default
+
+	use ogg || sed -i -e 's/HAVE_OGG 1/HAVE_OGG 0/' gen_das_config_h.sh
+	use mp3 || sed -i -e 's/HAVE_LAME 1/HAVE_LAME 0/' -e '/COMPILEFLAGS -lmp3lame/d' gen_das_config_h.sh
+	use osc || sed -i -e 's/HAVE_LIBLO 1/HAVE_LIBLO 0/' -e '/COMPILEFLAGS .* liblo/d' gen_das_config_h.sh
+}
+
+src_compile() {
+	tc-export CC CXX
+
+	emake PKG_CONFIG="$(tc-getPKG_CONFIG)" PREFIX="${EPREFIX}/usr" jack_capture
+}
+
+src_install() {
+	dobin jack_capture
+
+	dodoc "${DOCS[@]}"
+}