media-sound/supercollider: bump to 3.8.1

Closes: https://github.com/gentoo/gentoo/pull/8929

2 files changed, 117 insertions, 0 deletions

diff --git a/media-sound/supercollider/Manifest b/media-sound/supercollider/Manifest
index e99c4acb90ea..b844263e2512 100644
--- a/media-sound/supercollider/Manifest
+++ b/media-sound/supercollider/Manifest
@@ -1 +1,2 @@
 DIST SuperCollider-3.8.0-Source-linux.tar.bz2 8866545 BLAKE2B cace10861c4d8914d2a9279d72d8684c2914db3802d5922b1254ad96a8f0e7503f912afa3acd79125838d09d407aee5a5ec2e2f89345ff927120f5fcd666b5ca SHA512 305898067cb323682ca3dc65b3f093658192dbad228632d928f2fbd4a635c651f49e2e4f32c338997aafd48a22b739cd80de4296f747c3f1810ddede0aff283a
+DIST SuperCollider-3.8.1-Source-linux.tar.bz2 8913640 BLAKE2B 998b64b7e3530f6dc2e5d329bf387bb62aa694ec65d9a8464ae2b3bc1816f6a6fb26f351465df58170034ba35d7afc5df545a9bd614e96e6434155c70715d0ce SHA512 50d9e65e8b610e86decc98ecfa5bef2088af6dc2436e5059e5aa66e8ce9b4f2dab23dd1c5231c08430d1c50b211c876e7860c0e2078d0500bf8de4fbb9554eb7
diff --git a/media-sound/supercollider/supercollider-3.8.1.ebuild b/media-sound/supercollider/supercollider-3.8.1.ebuild
new file mode 100644
index 000000000000..07406d0c4346
--- /dev/null
+++ b/media-sound/supercollider/supercollider-3.8.1.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils readme.gentoo-r1 xdg-utils
+
+DESCRIPTION="An environment and a programming language for real time audio synthesis."
+HOMEPAGE="https://supercollider.github.io/"
+SRC_URI="https://github.com/supercollider/supercollider/releases/download/Version-${PV}/SuperCollider-${PV}-Source-linux.tar.bz2"
+
+LICENSE="GPL-2 gpl3? ( GPL-3 )"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="avahi cpu_flags_x86_sse cpu_flags_x86_sse2 debug emacs +fftw gedit +gpl3 jack qt5 server +sndfile static-libs vim"
+RESTRICT="mirror"
+
+RDEPEND="
+	media-libs/alsa-lib
+	sys-libs/readline:0=
+	x11-libs/libX11
+	x11-libs/libXt
+	avahi? ( net-dns/avahi )
+	fftw? ( sci-libs/fftw:3.0= )
+	jack? ( virtual/jack )
+	!jack? ( media-libs/portaudio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwebkit:5
+		dev-qt/qtwidgets:5
+	)
+	server? ( !app-admin/supernova )
+	sndfile? ( media-libs/libsndfile )
+"
+DEPEND="${RDEPEND}
+	dev-libs/icu
+	virtual/pkgconfig
+	emacs? ( virtual/emacs )
+	gedit? ( app-editors/gedit )
+	qt5? (
+		dev-qt/linguist-tools:5
+		dev-qt/qtdeclarative:5
+		dev-qt/qtconcurrent:5
+	)
+	vim? ( app-editors/vim )
+"
+
+S="${WORKDIR}/SuperCollider-Source"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.8.0-no-opengl.patch
+	"${FILESDIR}"/${PN}-3.8.0-no-qtsensors.patch
+	"${FILESDIR}"/${PN}-3.8.0-no-qtpositioning.patch
+	"${FILESDIR}"/${PN}-3.8.0-multilib.patch
+	"${FILESDIR}"/${PN}-3.8.0-gcc-7.patch
+	"${FILESDIR}"/${PN}-3.8.0-desktop.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DAUDIOAPI=$(usex jack jack portaudio)
+		-DINSTALL_HELP=ON
+		-DSYSTEM_BOOST=OFF
+		-DSYSTEM_YAMLCPP=OFF
+		-DNO_AVAHI=$(usex !avahi)
+		-DFFT_GREEN=$(usex !fftw)
+		-DNO_GPL3=$(usex !gpl3)
+		-DNO_LIBSNDFILE=$(usex !sndfile)
+		-DSC_QT=$(usex qt5)
+		-DSCLANG_SERVER=$(usex server)
+		-DSUPERNOVA=$(usex server)
+		-DLIBSCSYNTH=$(usex !static-libs)
+		-DSSE=$(usex cpu_flags_x86_sse)
+		-DSSE2=$(usex cpu_flags_x86_sse2)
+		-DSC_IDE=$(usex qt5)
+		-DSC_ED=$(usex gedit)
+		-DSC_VIM=$(usex vim)
+		-DSC_EL=$(usex emacs)
+	)
+
+	use debug && mycmakeargs+=(
+		-DSC_MEMORY_DEBUGGING=ON
+		-DSN_MEMORY_DEBUGGING=ON
+		-DGC_SANITYCHECK=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use vim && newdoc editors/scvim/README.md README.vim
+	use emacs && newdoc editors/scel/README.md README.emacs
+	use gedit && newdoc editors/sced/README.md README.gedit
+}
+
+pkg_postinst() {
+	einfo
+	einfo "Notice: SuperCollider is not very intuitive to get up and running."
+	einfo "The best course of action to make sure that the installation was"
+	einfo "successful and get you started with using SuperCollider is to take"
+	einfo "a look through ${EROOT%/}/usr/share/doc/${PF}/README.md.bz2"
+	einfo
+
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}