media-sound/upmpdcli: Bump to 1.5.0

Signed-off-by: Erik Mackdanz <stasibear@gentoo.org>
Package-Manager: Portage-3.0.9, Repoman-3.0.2

1 files changed, 49 insertions, 0 deletions

diff --git a/media-sound/upmpdcli/upmpdcli-1.5.0.ebuild b/media-sound/upmpdcli/upmpdcli-1.5.0.ebuild
new file mode 100644
index 000000000000..5c2fe3e85607
--- /dev/null
+++ b/media-sound/upmpdcli/upmpdcli-1.5.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd
+
+DESCRIPTION="UPnP Media Renderer front-end for MPD, the Music Player Daemon"
+HOMEPAGE="https://www.lesbonscomptes.com/upmpdcli/index.html"
+LICENSE="GPL-2"
+
+SRC_URI="https://www.lesbonscomptes.com/upmpdcli/downloads/${P}.tar.gz"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="thirdparty"
+
+DEPEND="
+	dev-libs/jsoncpp
+	media-libs/libmpdclient
+	net-libs/libmicrohttpd
+	>=net-libs/libupnpp-0.19.0
+"
+RDEPEND="
+	${DEPEND}
+	acct-group/upmpdcli
+	acct-user/upmpdcli
+	app-misc/recoll
+	thirdparty? ( dev-python/requests )
+"
+
+src_install() {
+	default
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	systemd_dounit systemd/upmpdcli.service
+}
+
+pkg_postinst() {
+	einfo
+	einfo "This package no longer assumes that upmpdcli is driving an"
+	einfo "mpd instance on the same host (https://bugs.gentoo.org/670130)."
+	einfo "Probably it is though, so be sure your mpd is built with"
+	einfo "USE=curl."
+	einfo
+	einfo "Consider installing media-sound/sc2mpd.  If upmpdcli"
+	einfo "detects sc2mpd at run-time, capabilities are added"
+	einfo "including internet radio support.  See upstream docs"
+	einfo "for more information."
+}