media-sound/hydrogen: bump to 1.2.0

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 99 insertions, 1 deletions

diff --git a/media-sound/hydrogen/Manifest b/media-sound/hydrogen/Manifest
index 054fe7a8b71f..6527063b4adf 100644
--- a/media-sound/hydrogen/Manifest
+++ b/media-sound/hydrogen/Manifest
@@ -1 +1,2 @@
 DIST hydrogen-1.1.1.tar.gz 11417837 BLAKE2B 52f6f61fc6e247875688dcea2290d92eb7bc85910620f0adcb52506d587b02dcaec6e2ecb72c77cf4eb3134534c75fc64bc4dd76a63f886cc6ea07d9b8812089 SHA512 c5e6bd713a0f9ef3b30bf0ae00bc41fea7494c20342c14c9f41ec05d1fdd3be721ffc3ff92bacd011e3b39a68022ea04daf55e60d334f64a00abef17d892cd37
+DIST hydrogen-1.2.0.tar.gz 12911501 BLAKE2B 606bfd977e67a962933e331bd1d4985a898e14c3d72656aa38fc3d50fa1daeb301a00778114e46a4890af548816befc8deb598bbc65a122e8a36694ce7740776 SHA512 610dc292ab26880897030ee7e969caf11e2758e0cccdc15b21711a2114564e12af855b50f0cf13964689b6697255c5f2080e2114c916ea6fbe3909057e7de1df
diff --git a/media-sound/hydrogen/hydrogen-1.2.0.ebuild b/media-sound/hydrogen/hydrogen-1.2.0.ebuild
new file mode 100644
index 000000000000..7fc1c8c951be
--- /dev/null
+++ b/media-sound/hydrogen/hydrogen-1.2.0.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Advanced drum machine"
+HOMEPAGE="http://www.hydrogen-music.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}-music/${PN}"
+else
+	MY_PV=${PV/_/-}
+	SRC_URI="https://github.com/${PN}-music/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+fi
+
+LICENSE="GPL-2 ZLIB"
+SLOT="0"
+IUSE="alsa +archive doc jack ladspa lash osc oss portaudio portmidi pulseaudio"
+
+REQUIRED_USE="lash? ( alsa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+CDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	>=media-libs/libsndfile-1.0.18
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	!archive? ( dev-libs/libtar )
+	doc? ( dev-texlive/texlive-fontutils )
+	jack? ( virtual/jack )
+	ladspa? ( media-libs/liblrdf )
+	lash? ( media-sound/lash )
+	osc? ( media-libs/liblo )
+	portaudio? ( media-libs/portaudio )
+	portmidi? ( media-libs/portmidi )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+DEPEND="
+	${CDEPEND}
+	dev-qt/qttest:5
+"
+RDEPEND="${CDEPEND}"
+
+DOCS=( AUTHORS ChangeLog DEVELOPERS README.md )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.1.0-gnuinstalldirs.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWANT_ALSA=$(usex alsa)
+		-DWANT_CPPUNIT=OFF
+		-DWANT_DEBUG=OFF
+		-DWANT_JACK=$(usex jack)
+		-DWANT_LADSPA=$(usex ladspa)
+		-DWANT_LASH=$(usex lash)
+		-DWANT_LIBARCHIVE=$(usex archive)
+		-DWANT_LRDF=$(usex ladspa)
+		-DWANT_OSC=$(usex osc)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PORTAUDIO=$(usex portaudio)
+		-DWANT_PORTMIDI=$(usex portmidi)
+		-DWANT_PULSEAUDIO=$(usex pulseaudio)
+		-DWANT_RUBBERBAND=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/docs/html/. )
+	cmake_src_install
+}
diff --git a/media-sound/hydrogen/hydrogen-9999.ebuild b/media-sound/hydrogen/hydrogen-9999.ebuild
index b93c44605a79..7fc1c8c951be 100644
--- a/media-sound/hydrogen/hydrogen-9999.ebuild
+++ b/media-sound/hydrogen/hydrogen-9999.ebuild
@@ -39,7 +39,7 @@ CDEPEND="
 	>=media-libs/libsndfile-1.0.18
 	alsa? ( media-libs/alsa-lib )
 	archive? ( app-arch/libarchive )
-	!archive? ( >=dev-libs/libtar-1.2.11-r3 )
+	!archive? ( dev-libs/libtar )
 	doc? ( dev-texlive/texlive-fontutils )
 	jack? ( virtual/jack )
 	ladspa? ( media-libs/liblrdf )