media-tv/kodi: update live ebuilds, add 20.9999, drop 19.9999

Closes: https://bugs.gentoo.org/913858
Closes: https://bugs.gentoo.org/919856
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

4 files changed, 778 insertions, 541 deletions

diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index 6e9e7f54540a..7df357cd443f 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -1,6 +1,8 @@
+DIST apache-groovy-binary-4.0.16.zip 29793704 BLAKE2B 30f77c6400c85821cf78f6ba1070da1e68644531f85f71cf7695443b13b81393cc89d4103eb869d1523f0a22a6e1c3428dcabf4f79c8a2c6eb2a6dea74e84e8f SHA512 743698979c801f3cfb36545888b5303e1e25dae5692bb45cab7ebbe102a6eda31f09abc6978349ad90ecaf630416fc87eacba7781244855e7e771a3c44041fa0
+DIST commons-lang3-3.14.0-bin.tar.gz 9442785 BLAKE2B 2ecdd06f97ac2688220055a08f67da9b859bed3ab00ff41800d5d9a1cebda599db2e816425c10c265dd6827a0ef79fc3dd094a8b3c9b9ae4ceae8f5750a59cf2 SHA512 8e7e62418a49ba810512c13a640a8bf35f878fcd54af32fdaab1111e37817f58b21b475980ba663fba4887e45ef8d88af8ff17796f20d202e929e8e2574546dc
+DIST commons-text-1.11.0-bin.tar.gz 3018564 BLAKE2B c32e41c6b8c90dea876caf4c2cedc9358d5e49506bfee7aee42ac6b92dbe8505d5e5d81c860a739bb06214b832cc29e91ddb95f3cfc24515c970302a519a5e43 SHA512 2e94877000dd270b69e2e8cbf49f258a90b4c628b6b6b0814e300a2f0e9c391f0816dceb0707e596ae3b7c9532f93e7a4917df47c77f44b3a810e14042ce5f3f
 DIST ffmpeg-kodi-4.3.2-Matrix-19.1.tar.gz 13490949 BLAKE2B 90007f2c4bac0e0a52b419d9333cf75b00e291f1ea7447cbdc579ee2f860de7c436c924253600f3fbd6e3faaabe97aaf46db083a5bbd2f5f03badcca5d643e89 SHA512 d3719253d674b16638b873545583b82fba3176803c81ba8bcb37e90456dd956f1c2ee8996493840cff2d61c6399f06ed0524a759f46e4ce174bce23e9c6eda4a
 DIST ffmpeg-kodi-4.4.1-Nexus-Alpha1.tar.gz 13725564 BLAKE2B 51d310e7000aeba657d55341c5fdb540474e197b85062228ab4b314c8309ec11985aa7f105193333fc6106529e8e58c86eafe268190894be8532d0e0b9065fa6 SHA512 8beb04d577b5251e74b0d52f4d130997a8ba94bbd488c7c8309e6b45095c27807e150212888ce3a384b23dff52f8df1a7bde5407bae924ddc363f8125c0616c5
-DIST ffmpeg-kodi-5.1.2-Nexus-Alpha3.tar.gz 14416966 BLAKE2B fe35ef6a9aa2d60a2b34432ae8063850003d550208f223ea43af8ebcaa73e6993639e8cfe8a38676bac79e6b1816bd791b75b66ef58ff4d740bc9a5e0e7f9b78 SHA512 ce60852b8456d6f4bfc60de0ceadb33034d9b3eea8c0bc84d8b7199984ecbf334a2c4d9b42eade439d0ef30ce22e3b2ca0a49d4df837a18cd3136b4343ed3113
 DIST kodi-19.5-Matrix.tar.gz 53496968 BLAKE2B 89855e4d59faa5734e945e50267c2ec8d8e8bef91ecfa49ae49dd99f749a59609b55c57821042939082a8f98ea95f7edc3de0fa0494e218d454c67b79807ef87 SHA512 b560c068491a7f62894167da99be082f0e6a8a840cbfe1fb0cef5c844cda959bd3b5479a435b58616bb2a8454083ad393a4d49de05fbbdb0817a0fad9726e52f
 DIST kodi-20.3-Nexus.tar.gz 54567232 BLAKE2B 956be2d1bef16910d88f244331bdff60cce309d9596ec7939a459489b7fa7ab3ca7b29e2aca0de542f48f95321d86c9d7a606ac311a7a3c69e0e6f901511982e SHA512 cdec1383d33f421828f0249ac2929980c6eaa39e345a8a364d9f3479f873029a15f3f6e6d40707fd2df2067a71bdaa3c6a1e26277074c31c631c71afe7465cb4
 DIST libdvdcss-1.4.2-Leia-Beta-5.tar.gz 101068 BLAKE2B 283aa2cec0a2200d3569bc280cb9659e9224a6b3a77db8a35b269cd8caf1337ac9d8b92b806df66f63ef7458a46bd6261f0b8b14678b10e26644a79dcbeea5da SHA512 5185dbdbeb1bd13ea9d8723f1f4ab599d6f3102f5ba1096cd085aa1cda252c045f327c719227bba8e1b742352ade5e335106c8d0c1637a5a6b93ce661620dd7e
diff --git a/media-tv/kodi/kodi-19.9999.ebuild b/media-tv/kodi/kodi-19.9999.ebuild
deleted file mode 100644
index a0a2b98fb73a..000000000000
--- a/media-tv/kodi/kodi-19.9999.ebuild
+++ /dev/null
@@ -1,360 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_REQ_USE="sqlite,ssl"
-LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5"
-LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3"
-LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3"
-FFMPEG_VERSION="4.3.2"
-CODENAME="Matrix"
-FFMPEG_KODI_VERSION="19.1"
-PYTHON_COMPAT=( python3_{10..11} )
-SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
-	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
-	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
-	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
-if [[ ${PV} == *9999 ]] ; then
-	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
-	EGIT_BRANCH="Matrix"
-	inherit git-r3
-else
-	MY_PV=${PV/_p/_r}
-	MY_PV=${MY_PV/_alpha/a}
-	MY_PV=${MY_PV/_beta/b}
-	MY_PV=${MY_PV/_rc/RC}
-	MY_PV="${MY_PV}-${CODENAME}"
-	MY_P="${PN}-${MY_PV}"
-	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-	S=${WORKDIR}/xbmc-${MY_PV}
-fi
-
-inherit autotools cmake desktop libtool linux-info pax-utils python-single-r1 xdg
-
-DESCRIPTION="A free and open source media-player and entertainment hub"
-HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
-
-LICENSE="GPL-2+"
-SLOT="0"
-# use flag is called libusb so that it doesn't fool people in thinking that
-# it is _required_ for USB support. Otherwise they'll disable udev and
-# that's going to be worse.
-IUSE="airplay alsa bluetooth bluray caps cec +css dav1d dbus eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical power-control pulseaudio raspberry-pi samba +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
-IUSE="${IUSE} cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_arm_neon"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( gbm wayland X )
-	?? ( mariadb mysql )
-	bluray? ( udf )
-	udev? ( !libusb )
-	udisks? ( dbus )
-	upower? ( dbus )
-	power-control? ( dbus )
-	vdpau? (
-		X
-		!gles
-		!gbm
-	)
-	zeroconf? ( dbus )
-"
-RESTRICT="!test? ( test )"
-
-COMMON_DEPEND="
-	>=dev-libs/lzo-2.04
-	>=dev-libs/flatbuffers-1.12.0:=
-	>=media-libs/libjpeg-turbo-2.0.4:=
-	>=media-libs/libpng-1.6.26:0=
-"
-COMMON_TARGET_DEPEND="${PYTHON_DEPS}
-	airplay? (
-		>=app-pda/libplist-2.0.0
-		net-libs/shairplay
-	)
-	alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
-	bluetooth? ( net-wireless/bluez )
-	bluray? ( >=media-libs/libbluray-1.1.2 )
-	caps? ( sys-libs/libcap )
-	dbus? ( sys-apps/dbus )
-	dev-db/sqlite
-	<dev-libs/crossguid-0.2.2_p20190529
-	>=dev-libs/fribidi-1.0.5
-	cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] )
-	dev-libs/libpcre[cxx]
-	>=dev-libs/spdlog-1.5.0:=
-	dev-libs/tinyxml[stl]
-	$(python_gen_cond_dep '
-		dev-python/pillow[${PYTHON_USEDEP}]
-		dev-python/pycryptodome[${PYTHON_USEDEP}]
-	')
-	>=dev-libs/libcdio-2.1.0[cxx]
-	>=dev-libs/libfmt-6.1.2
-	dev-libs/libfstrcmp
-	gbm? (
-		>=dev-libs/libinput-1.10.5
-		media-libs/mesa[gbm(+)]
-		x11-libs/libxkbcommon
-	)
-	gles? (
-		!raspberry-pi? ( media-libs/mesa[gles2] )
-	)
-	lcms? ( media-libs/lcms:2 )
-	libusb? ( virtual/libusb:1 )
-	virtual/ttf-fonts
-	media-fonts/roboto
-	>=media-libs/freetype-2.10.1
-	>=media-libs/libass-0.13.4
-	!raspberry-pi? ( media-libs/mesa[egl(+)] )
-	>=media-libs/taglib-1.11.1
-	system-ffmpeg? (
-		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[dav1d?,encode,postproc]
-		=media-video/ffmpeg-4*[openssl]
-	)
-	!system-ffmpeg? (
-		app-arch/bzip2
-		dav1d? ( media-libs/dav1d )
-	)
-	mysql? ( dev-db/mysql-connector-c:= )
-	mariadb? ( dev-db/mariadb-connector-c:= )
-	>=net-misc/curl-7.68.0[http2]
-	nfs? ( >=net-fs/libnfs-2.0.0:= )
-	!gles? ( media-libs/glu )
-	>=dev-libs/openssl-1.1.1k:0=
-	raspberry-pi? (
-		|| ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl(+),gles2,video_cards_vc4] )
-	)
-	pulseaudio? ( media-libs/libpulse )
-	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
-	>=sys-libs/zlib-1.2.11
-	udf? ( >=dev-libs/libudfread-1.0.0 )
-	udev? ( virtual/udev )
-	vaapi? (
-		media-libs/libva:=
-		system-ffmpeg? ( media-video/ffmpeg[vaapi] )
-		wayland? ( media-libs/libva[wayland] )
-		X? ( media-libs/libva[X] )
-	)
-	virtual/libiconv
-	vdpau? (
-		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
-		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
-	)
-	wayland? (
-		>=dev-cpp/waylandpp-0.2.3:=
-		media-libs/mesa[wayland]
-		>=dev-libs/wayland-protocols-1.7
-		>=x11-libs/libxkbcommon-0.4.1
-	)
-	webserver? ( >=net-libs/libmicrohttpd-0.9.55:=[messages(+)] )
-	X? (
-		media-libs/mesa[X]
-		!gles? ( media-libs/libglvnd[X] )
-		x11-libs/libX11
-		x11-libs/libXrandr
-		x11-libs/libXrender
-		system-ffmpeg? ( media-video/ffmpeg[X] )
-	)
-	x11-libs/libdrm
-	xslt? (
-		dev-libs/libxslt
-		>=dev-libs/libxml2-2.9.4
-	)
-	zeroconf? ( net-dns/avahi[dbus] )
-"
-RDEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
-	lirc? ( app-misc/lirc )
-	power-control? ( || ( sys-apps/systemd sys-auth/elogind ) )
-	udisks? ( sys-fs/udisks:2 )
-	upower? ( sys-power/upower )
-"
-DEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
-	dev-libs/rapidjson
-	test? ( >=dev-cpp/gtest-1.10.0 )
-"
-BDEPEND="${COMMON_DEPEND}
-	dev-build/cmake
-	dev-lang/swig
-	media-libs/giflib
-	>=dev-libs/flatbuffers-1.11.0
-	>=media-libs/libjpeg-turbo-2.0.4:=
-	>=media-libs/libpng-1.6.26:0=
-	virtual/pkgconfig
-	virtual/jre
-"
-
-CONFIG_CHECK="~IP_MULTICAST"
-ERROR_IP_MULTICAST="
-In some cases Kodi needs to access multicast addresses.
-Please consider enabling IP_MULTICAST under Networking options.
-"
-
-pkg_setup() {
-	check_extra_config
-	python-single-r1_pkg_setup
-}
-
-src_unpack() {
-	if [[ ${PV} == *9999 ]] ; then
-		git-r3_src_unpack
-	else
-		default
-	fi
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	# avoid long delays when powerkit isn't running #348580
-	sed -i \
-		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
-		xbmc/platform/linux/*.cpp || die
-
-	# Prepare tools and libs witch are configured with autotools during compile time
-	AUTOTOOLS_DIRS=(
-		"${S}"/tools/depends/native/TexturePacker/src
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src
-	)
-
-	local d
-	for d in "${AUTOTOOLS_DIRS[@]}" ; do
-		pushd ${d} >/dev/null || die
-		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
-		popd >/dev/null || die
-	done
-	elibtoolize
-
-	# Prevent autoreconf rerun
-	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
-		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
-		|| die
-}
-
-src_configure() {
-	local platform=()
-	use gbm && platform+=( gbm )
-	use wayland && platform+=( wayland )
-	use X && platform+=( x11 )
-	local core_platform_name="${platform[@]}"
-	local mycmakeargs=(
-		-DENABLE_SSE=$(usex cpu_flags_x86_sse)
-		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
-		-DENABLE_SSE3=$(usex cpu_flags_x86_sse3)
-		-DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1)
-		-DENABLE_SSE4_2=$(usex cpu_flags_x86_sse4_2)
-		-DENABLE_AVX=$(usex cpu_flags_x86_avx)
-		-DENABLE_AVX2=$(usex cpu_flags_x86_avx2)
-		-DENABLE_NEON=$(usex cpu_flags_arm_neon)
-		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
-		-DVERBOSE=ON
-		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
-		-DENABLE_ALSA=$(usex alsa)
-		-DENABLE_AIRTUNES=$(usex airplay)
-		-DENABLE_AVAHI=$(usex zeroconf)
-		-DENABLE_BLUETOOTH=$(usex bluetooth)
-		-DENABLE_BLURAY=$(usex bluray)
-		-DENABLE_CCACHE=OFF
-		-DENABLE_CLANGFORMAT=OFF
-		-DENABLE_CLANGTIDY=OFF
-		-DENABLE_CPPCHECK=OFF
-		-DENABLE_ISO9660PP=$(usex optical)
-		-DENABLE_CEC=$(usex cec)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DVDCSS=$(usex css)
-		-DENABLE_EVENTCLIENTS=ON # alway enable to have 'kodi-send' and filter extra staff in 'src_install()'
-		-DENABLE_INTERNAL_CROSSGUID=OFF
-		-DENABLE_INTERNAL_RapidJSON=OFF
-		-DENABLE_INTERNAL_FMT=OFF
-		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
-		-DENABLE_INTERNAL_FSTRCMP=OFF
-		-DENABLE_INTERNAL_FLATBUFFERS=OFF
-		-DENABLE_INTERNAL_DAV1D=OFF
-		-DENABLE_INTERNAL_GTEST=OFF
-		-DENABLE_INTERNAL_UDFREAD=OFF
-		-DENABLE_INTERNAL_SPDLOG=OFF
-		-DENABLE_CAP=$(usex caps)
-		-DENABLE_LCMS2=$(usex lcms)
-		-DENABLE_LIRCCLIENT=$(usex lirc)
-		-DENABLE_MARIADBCLIENT=$(usex mariadb)
-		-DENABLE_MDNS=OFF # used only on Android
-		-DENABLE_MICROHTTPD=$(usex webserver)
-		-DENABLE_MYSQLCLIENT=$(usex mysql)
-		-DENABLE_NFS=$(usex nfs)
-		-DENABLE_OPENGLES=$(usex gles)
-		-DENABLE_OPENGL=$(usex !gles)
-		-DENABLE_OPTICAL=$(usex optical)
-		-DENABLE_PLIST=$(usex airplay)
-		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
-		-DENABLE_SMBCLIENT=$(usex samba)
-		-DENABLE_SNDIO=OFF
-		-DENABLE_TESTING=$(usex test)
-		-DENABLE_UDEV=$(usex udev)
-		-DENABLE_UDFREAD=$(usex udf)
-		-DENABLE_UPNP=$(usex upnp)
-		-DENABLE_VAAPI=$(usex vaapi)
-		-DENABLE_VDPAU=$(usex vdpau)
-		-DENABLE_XSLT=$(usex xslt)
-		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
-		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
-		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
-		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
-		-DPYTHON_LIBRARY="$(python_get_library_path)"
-		-DAPP_RENDER_SYSTEM="$(usex gles gles gl)"
-		-DCORE_PLATFORM_NAME="${core_platform_name}"
-	)
-
-	use !udev && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
-
-	use X && use !gles && mycmakeargs+=( -DENABLE_GLX=ON )
-
-	if use system-ffmpeg; then
-		mycmakeargs+=( -DWITH_FFMPEG="yes" )
-	else
-		mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
-	fi
-
-	if ! echo "${CFLAGS}" | grep -Fwqe '-DNDEBUG' - && ! echo "${CFLAGS}" | grep -Fwqe '-D_DEBUG' - ; then
-		CFLAGS+=' -DNDEBUG' # Kodi requires one of the 'NDEBUG' or '_DEBUG' defines
-		CXXFLAGS+=' -DNDEBUG'
-	fi
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile all
-}
-
-src_test() {
-	local myctestargs=(
-		# Known failing, unreliable test
-		# bug #743938
-		-E "(TestCPUInfo.GetCPUFrequency)"
-	)
-
-	# see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213
-	KODI_HOME="${BUILD_DIR}" cmake_build check
-}
-
-src_install() {
-	cmake_src_install
-
-	pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
-
-	newicon media/icon48x48.png kodi.png
-
-	rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
-	dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
-		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
-
-	if use !eventclients ; then
-		rm -f "${ED}"/usr/bin/kodi-ps3remote || die
-		rm -f "${D}"$(python_get_sitedir)/kodi/ps3_remote.py || die
-		rm -rf "${D}"$(python_get_sitedir)/kodi/ps3 || die
-		rm -rf "${D}"$(python_get_sitedir)/kodi/bt || die
-		rm -rf "${ED}"/usr/share/doc/${PF}/kodi-eventclients-dev || die
-	fi
-
-	python_optimize "${D}$(python_get_sitedir)"
-}
diff --git a/media-tv/kodi/kodi-20.9999.ebuild b/media-tv/kodi/kodi-20.9999.ebuild
new file mode 100644
index 000000000000..893bd5d6c5b5
--- /dev/null
+++ b/media-tv/kodi/kodi-20.9999.ebuild
@@ -0,0 +1,474 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# FFmpeg can be unbundled, but is currently stuck at a very old version.
+# libdvd{css,read,nav} are not unbundlable without patching the buildsystem.
+
+# Versions for the forked projects that are bundled
+# See tools/depends/target/<project>/<project>-VERSION
+LIBDVDCSS_VERSION="1.4.3-Next-Nexus-Alpha2-2"
+LIBDVDREAD_VERSION="6.1.3-Next-Nexus-Alpha2-2"
+LIBDVDNAV_VERSION="6.1.1-Next-Nexus-Alpha2-2"
+FFMPEG_VERSION="4.4.1"
+CODENAME="Nexus"
+FFMPEG_KODI_VERSION="Alpha1"
+
+# Doesn't build with jdk-21
+_JAVA_PKG_WANT_BUILD_VM=( {openjdk{,-jre},icedtea}{,-bin}-{8,11,17} )
+JAVA_PKG_WANT_BUILD_VM=${_JAVA_PKG_WANT_BUILD_VM[@]}
+# Required to be set, but not used.
+JAVA_PKG_WANT_SOURCE="17"
+JAVA_PKG_WANT_TARGET="17"
+
+PYTHON_REQ_USE="sqlite,ssl"
+PYTHON_COMPAT=( python3_{10..11} ) # python3.12 support added in 21
+
+CPU_FLAGS="cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_arm_neon"
+
+inherit cmake desktop flag-o-matic java-pkg-2 linux-info optfeature pax-utils python-single-r1 xdg
+
+DESCRIPTION="A free and open source media-player and entertainment hub"
+HOMEPAGE="https://kodi.tv/"
+
+SRC_URI="
+	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz
+		-> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
+	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz
+		-> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
+	css? (
+		https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz
+			-> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
+	)
+	!system-ffmpeg? (
+		https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz
+			-> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz
+	)
+"
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
+	if [[ ${PV} != "9999" ]]; then
+		EGIT_BRANCH="${CODENAME}"
+	fi
+	inherit git-r3
+else
+	MY_PV=${PV/_p/_r}
+	MY_PV=${MY_PV/_alpha/a}
+	MY_PV=${MY_PV/_beta/b}
+	MY_PV=${MY_PV/_rc/RC}
+	MY_PV="${MY_PV}-${CODENAME}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S=${WORKDIR}/xbmc-${MY_PV}
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+# use flag is called libusb so that it doesn't fool people in thinking that
+# it is _required_ for USB support. Otherwise they'll disable udev and
+# that's going to be worse.
+IUSE="airplay alsa bluetooth bluray caps cec +css dbus doc eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical pipewire pulseaudio raspberry-pi samba system-ffmpeg test udf udev upnp vaapi vdpau wayland webserver X +xslt zeroconf ${CPU_FLAGS}"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	^^ ( gbm wayland X )
+	?? ( mariadb mysql )
+	bluray? ( udf )
+	gbm? ( udev )
+	udev? ( !libusb )
+	vdpau? ( X !gles !gbm )
+	zeroconf? ( dbus )
+"
+RESTRICT="!test? ( test )"
+
+# dev-libs/libcec[-cubox] bug #818262
+COMMON_DEPEND="
+	>=dev-libs/flatbuffers-1.12.0:=
+	>=dev-libs/lzo-2.04:2
+	media-libs/giflib:=
+	>=media-libs/libjpeg-turbo-2.0.4:=
+	>=media-libs/libpng-1.6.26:0=
+	wayland? (
+		dev-cpp/waylandpp:=
+	)
+"
+COMMON_TARGET_DEPEND="${PYTHON_DEPS}
+	>=net-misc/curl-7.68.0[http2]
+	>=sys-libs/zlib-1.2.11
+	dev-db/sqlite:3
+	dev-libs/crossguid
+	>=dev-libs/fribidi-1.0.5
+	>=dev-libs/libcdio-2.1.0:=[cxx]
+	>=dev-libs/libfmt-6.1.2:=
+	dev-libs/libfstrcmp
+	dev-libs/libpcre[cxx]
+	>=dev-libs/openssl-1.1.1k:0=
+	>=dev-libs/spdlog-1.5.0:=
+	dev-libs/tinyxml[stl]
+	media-fonts/roboto
+	media-libs/libglvnd[X?]
+	>=media-libs/freetype-2.10.1
+	media-libs/harfbuzz:=
+	>=media-libs/libass-0.13.4:=
+	media-libs/mesa[egl(+),gbm(+)?,wayland?,X?]
+	>=media-libs/taglib-1.9.0
+	sci-libs/kissfft
+	virtual/libiconv
+	virtual/ttf-fonts
+	x11-libs/libdrm
+	$(python_gen_cond_dep '
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	')
+	airplay? (
+		>=app-pda/libplist-2.0.0:=
+		net-libs/shairplay
+	)
+	alsa? (
+		>=media-libs/alsa-lib-1.1.4.1
+	)
+	bluetooth? (
+		net-wireless/bluez:=
+	)
+	bluray? (
+		>=media-libs/libbluray-1.1.2:=
+	)
+	caps? (
+		sys-libs/libcap
+	)
+	cec? (
+		>=dev-libs/libcec-4.0[-cubox,raspberry-pi?]
+	)
+	dbus? (
+		sys-apps/dbus
+	)
+	gbm? (
+		>=dev-libs/libinput-1.10.5:=
+		x11-libs/libxkbcommon
+	)
+	gles? (
+		!raspberry-pi? (
+			media-libs/mesa[gles2]
+		)
+	)
+	!gles? (
+		media-libs/glu
+	)
+	lcms? (
+		>=media-libs/lcms-2.10:2
+	)
+	libusb? (
+		virtual/libusb:1
+	)
+	lirc? (
+		app-misc/lirc
+	)
+	mariadb? (
+		dev-db/mariadb-connector-c:=
+	)
+	mysql? (
+		dev-db/mysql-connector-c:=
+	)
+	nfs? (
+		>=net-fs/libnfs-2.0.0:=
+	)
+	pipewire? (
+		>=media-video/pipewire-0.3.24:=
+	)
+	pulseaudio? (
+		media-libs/libpulse
+	)
+	raspberry-pi? (
+		|| (
+			media-libs/raspberrypi-userland
+			media-libs/raspberrypi-userland-bin
+			media-libs/mesa[gles2,video_cards_vc4]
+		)
+	)
+	samba? (
+		>=net-fs/samba-3.4.6[smbclient(+)]
+	)
+	system-ffmpeg? (
+		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,postproc,vaapi?,vdpau?,X?]
+		=media-video/ffmpeg-4*[openssl]
+	)
+	!system-ffmpeg? (
+		app-arch/bzip2
+		media-libs/dav1d:=
+	)
+	udf? (
+		>=dev-libs/libudfread-1.0.0
+	)
+	udev? (
+		virtual/libudev:=
+	)
+	vaapi? (
+		media-libs/libva:=[wayland?,X?]
+	)
+	vdpau? (
+		|| (
+			>=x11-libs/libvdpau-1.1
+			>=x11-drivers/nvidia-drivers-180.51
+		)
+	)
+	wayland? (
+		>=x11-libs/libxkbcommon-0.4.1[wayland]
+	)
+	webserver? (
+		>=net-libs/libmicrohttpd-0.9.55:=[messages(+)]
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXrandr
+	)
+	xslt? (
+		dev-libs/libxslt
+		>=dev-libs/libxml2-2.9.4
+	)
+	zeroconf? (
+		net-dns/avahi[dbus]
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	${COMMON_TARGET_DEPEND}
+"
+DEPEND="
+	${COMMON_DEPEND}
+	${COMMON_TARGET_DEPEND}
+	dev-libs/rapidjson
+	test? (
+		>=dev-cpp/gtest-1.10.0
+	)
+	wayland? (
+		>=dev-libs/wayland-protocols-1.7
+	)
+	X? (
+		x11-base/xorg-proto
+		x11-libs/libXrender
+	)
+"
+# <dev-lang/swig-4.2.0 https://github.com/xbmc/xbmc/issues/24385
+BDEPEND="
+	${COMMON_DEPEND}
+	dev-build/cmake
+	<dev-lang/swig-4.2.0
+	virtual/pkgconfig
+	<=virtual/jre-17:*
+	doc? (
+		app-text/doxygen
+	)
+"
+
+# bug #544020
+CONFIG_CHECK="~IP_MULTICAST"
+ERROR_IP_MULTICAST="
+In some cases Kodi needs to access multicast addresses.
+Please consider enabling IP_MULTICAST under Networking options.
+"
+
+PATCHES=(
+	"${FILESDIR}"/kodi-20.2-binutils-2.41.patch
+)
+
+pkg_setup() {
+	check_extra_config
+	java-pkg-2_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999 ]] ; then
+		git-r3_src_unpack
+	else
+		unpack ${MY_P}.tar.gz
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# avoid long delays when powerkit isn't running #348580
+	sed -i \
+		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
+		xbmc/platform/linux/*.cpp || die
+
+	# Add all possible names for kissfft libraries
+	for datatype in {float,int16,int32,simd}; do
+		sed -i \
+			-e "s/\(find_library(KISSFFT_LIBRARY NAMES .*\)/\1 kissfft-${datatype} kissfft-${datatype}-openmp/" \
+			cmake/modules/FindKissFFT.cmake || die
+	done
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-Wno-dev # less noise
+
+		-DAPP_RENDER_SYSTEM=$(usex gles gles gl)
+		-DCORE_PLATFORM_NAME=$(usev gbm)$(usev wayland)$(usev X x11)
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+		-DENABLE_TESTING=$(usex test)
+		-DVERBOSE=ON
+
+		# Enforce use of configured python interpeter
+		-DPYTHON_PATH=$(python_get_library_path)
+		-DPYTHON_VER=${EPYTHON##python} # wont work for pypy
+
+		# Toolchain
+		-DENABLE_CCACHE=OFF
+		-DENABLE_CLANGFORMAT=OFF
+		-DENABLE_CLANGTIDY=OFF
+		-DENABLE_CPPCHECK=OFF
+		-DENABLE_INCLUDEWHATYOUUSE=OFF
+		# https://bugs.gentoo.org/show_bug.cgi?id=606124
+		-DENABLE_GOLD=OFF
+		-DENABLE_LLD=OFF
+		-DENABLE_MOLD=OFF
+		-DUSE_LTO=OFF
+
+		# Features
+		-DENABLE_AIRTUNES=$(usex airplay)
+		-DENABLE_ALSA=$(usex alsa)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_BLUETOOTH=$(usex bluetooth)
+		-DENABLE_BLURAY=$(usex bluray)
+		-DENABLE_CAP=$(usex caps)
+		-DENABLE_CEC=$(usex cec)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DVDCSS=$(usex css)
+		-DENABLE_EVENTCLIENTS=ON # alway enable to have 'kodi-send' and filter extra staff in 'src_install()'
+		-DENABLE_ISO9660PP=$(usex optical)
+		-DENABLE_LCMS2=$(usex lcms)
+		-DENABLE_LIRCCLIENT=$(usex lirc)
+		-DENABLE_MARIADBCLIENT=$(usex mariadb)
+		-DENABLE_MDNS=OFF # used only on Android
+		-DENABLE_MICROHTTPD=$(usex webserver)
+		-DENABLE_MYSQLCLIENT=$(usex mysql)
+		-DENABLE_NFS=$(usex nfs)
+		-DENABLE_OPENGL=$(usex !gles)
+		-DENABLE_OPENGLES=$(usex gles)
+		-DENABLE_OPTICAL=$(usex optical)
+		-DENABLE_PIPEWIRE=$(usex pipewire)
+		-DENABLE_PLIST=$(usex airplay)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
+		-DENABLE_SMBCLIENT=$(usex samba)
+		-DENABLE_SNDIO=OFF
+		-DENABLE_UDEV=$(usex udev)
+		-DENABLE_UDFREAD=$(usex udf)
+		-DENABLE_UPNP=$(usex upnp)
+		-DENABLE_VAAPI=$(usex vaapi)
+		-DENABLE_VDPAU=$(usex vdpau)
+		-DENABLE_XSLT=$(usex xslt)
+
+		#To bundle or not
+		-DENABLE_INTERNAL_CROSSGUID=OFF
+		-DENABLE_INTERNAL_DAV1D=OFF
+		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
+		-DENABLE_INTERNAL_FLATBUFFERS=OFF
+		-DENABLE_INTERNAL_FMT=OFF
+		-DENABLE_INTERNAL_FSTRCMP=OFF
+		-DENABLE_INTERNAL_GTEST=OFF
+		-DENABLE_INTERNAL_KISSFFT=OFF
+		-DENABLE_INTERNAL_PCRE=OFF
+		-DENABLE_INTERNAL_RapidJSON=OFF
+		-DENABLE_INTERNAL_SPDLOG=OFF
+		-DENABLE_INTERNAL_TAGLIB=OFF
+		-DENABLE_INTERNAL_UDFREAD=OFF
+
+		-DWITH_FFMPEG=$(usex system-ffmpeg)
+
+		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
+		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
+	)
+
+	# Separated to avoid "Manually-specified variables were not used by the project:"
+	use css && mycmakeargs+=( -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz" )
+	use !system-ffmpeg && mycmakeargs+=(
+		-DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz"
+	)
+	use nfs && mycmakeargs+=( -DENABLE_INTERNAL_NFS=OFF )
+	use !udev && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
+	use X && use !gles && mycmakeargs+=( -DENABLE_GLX=ON )
+
+	for flag in ${CPU_FLAGS[@]} ; do
+		local name=${flag#cpu_flags_*_}
+		mycmakeargs+=( -DENABLE_${name^^}=$(usex ${flag}) )
+	done
+
+	if ! is-flag -DNDEBUG && ! is-flag -D_DEBUG ; then
+		# Kodi requires one of the 'NDEBUG' or '_DEBUG' defines
+		append-cflags -DNDEBUG
+		append-cxxflags -DNDEBUG
+	fi
+
+	# Violates ODR (bug #860984) and USE_LTO does spooky stuff
+	# https://github.com/xbmc/xbmc/commit/cb72a22d54a91845b1092c295f84eeb48328921e
+	filter-lto
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile all
+	use doc && cmake_build doc
+	use test && cmake_build kodi-test
+}
+
+src_test() {
+	local -x CMAKE_SKIP_TESTS=(
+		# Known failing, unreliable test
+		# bug #743938
+		TestCPUInfo.GetCPUFrequency
+		# Test failure stemming from sci-libs/kissfft
+		# The difference between output[2i] and (i==freq1?1.0:0.0) is inf, which exceeds 1e-7, where output[2i]
+		# evaluates to inf,(i==freq1?1.0:0.0) evaluates to 0, and 1e-7 evaluates to 9.9999999999999995e-08.
+		TestRFFT.SimpleSignal
+		# bug #779184
+		# https://github.com/xbmc/xbmc/issues/18594
+		$(usev x86 TestDateTime.SetFromDBTime)
+	)
+
+	# see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213
+	local -x KODI_HOME="${BUILD_DIR}"
+
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	# bug #457588
+	pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
+
+	newicon media/icon48x48.png kodi.png
+
+	rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
+	dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
+		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
+
+	if use !eventclients ; then
+		rm -f "${ED}"/usr/bin/kodi-ps3remote || die
+		rm -f "${D}"$(python_get_sitedir)/kodi/ps3_remote.py || die
+		rm -rf "${D}"$(python_get_sitedir)/kodi/ps3 || die
+		rm -rf "${D}"$(python_get_sitedir)/kodi/bt || die
+		rm -rf "${ED}"/usr/share/doc/${PF}/kodi-eventclients-dev || die
+	fi
+
+	python_optimize "${D}$(python_get_sitedir)"
+
+	einstalldocs
+	use doc && dodoc -r "${S}"/docs/html/
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use dbus ; then
+		optfeature "getting battery level and active power source" sys-power/upower
+		optfeature "control of shutdown, reboot, suspend, and hibernate" sys-auth/elogind sys-apps/systemd
+		optfeature "storage management support (automounting, volume monitoring, etc)" sys-fs/udisks:2
+	fi
+}
diff --git a/media-tv/kodi/kodi-9999.ebuild b/media-tv/kodi/kodi-9999.ebuild
index 3c0e0c77affa..5d6b97caa74d 100644
--- a/media-tv/kodi/kodi-9999.ebuild
+++ b/media-tv/kodi/kodi-9999.ebuild
@@ -1,188 +1,265 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-PYTHON_REQ_USE="sqlite,ssl"
+CODENAME="Omega"
+
+# libdvd{css,read,nav} are not unbundlable without patching the buildsystem.
+
+# Versions for the forked projects that are bundled
+# See tools/depends/target/<project>/<project>-VERSION
 LIBDVDCSS_VERSION="1.4.3-Next-Nexus-Alpha2-2"
 LIBDVDREAD_VERSION="6.1.3-Next-Nexus-Alpha2-2"
 LIBDVDNAV_VERSION="6.1.1-Next-Nexus-Alpha2-2"
-FFMPEG_VERSION="5.1.2"
-CODENAME="Nexus"
-FFMPEG_KODI_VERSION="Alpha3"
-PYTHON_COMPAT=( python3_{10..11} )
-SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
-	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
-	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
-	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
+
+# Java bundles from xbmc/interfaces/swig/CMakeLists.txt
+GROOVY_VERSION="4.0.16"
+APACHE_COMMON_LANG_VERSION="3.14.0"
+APACHE_COMMON_TEXT_VERSION="1.11.0"
+
+# Doesn't build with jdk-21
+_JAVA_PKG_WANT_BUILD_VM=( {openjdk{,-jre},icedtea}{,-bin}-{8,11,17} )
+JAVA_PKG_WANT_BUILD_VM=${_JAVA_PKG_WANT_BUILD_VM[@]}
+# Required to be set, but not used.
+JAVA_PKG_WANT_SOURCE="17"
+JAVA_PKG_WANT_TARGET="17"
+
+PYTHON_REQ_USE="sqlite,ssl"
+PYTHON_COMPAT=( python3_{10..12} )
+
+CPU_FLAGS="cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_arm_neon"
+
+inherit cmake desktop flag-o-matic java-pkg-2 linux-info optfeature pax-utils python-single-r1 xdg
+
+DESCRIPTION="A free and open source media-player and entertainment hub"
+HOMEPAGE="https://kodi.tv/"
+
+SRC_URI="
+	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz
+		-> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
+	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz
+		-> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
+	https://mirrors.kodi.tv/build-deps/sources/apache-groovy-binary-${GROOVY_VERSION}.zip
+	https://mirrors.kodi.tv/build-deps/sources/commons-lang3-${APACHE_COMMON_LANG_VERSION}-bin.tar.gz
+	https://mirrors.kodi.tv/build-deps/sources/commons-text-${APACHE_COMMON_TEXT_VERSION}-bin.tar.gz
+	css? (
+		https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz
+			-> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
+	)
+"
 if [[ ${PV} == *9999 ]] ; then
 	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
+	if [[ ${PV} != "9999" ]]; then
+		EGIT_BRANCH="${CODENAME}"
+	fi
 	inherit git-r3
 else
 	MY_PV=${PV/_p/_r}
 	MY_PV=${MY_PV/_alpha/a}
 	MY_PV=${MY_PV/_beta/b}
 	MY_PV=${MY_PV/_rc/RC}
+	MY_PV="${MY_PV}-${CODENAME}"
 	MY_P="${PN}-${MY_PV}"
-	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz"
+	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-	S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
+	S=${WORKDIR}/xbmc-${MY_PV}
 fi
 
-inherit autotools cmake desktop libtool linux-info pax-utils python-single-r1 xdg
-
-DESCRIPTION="A free and open source media-player and entertainment hub"
-HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
-
 LICENSE="GPL-2+"
 SLOT="0"
 # use flag is called libusb so that it doesn't fool people in thinking that
 # it is _required_ for USB support. Otherwise they'll disable udev and
 # that's going to be worse.
-IUSE="airplay alsa bluetooth bluray caps cec +css dav1d dbus eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical pipewire power-control pulseaudio raspberry-pi samba +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
-IUSE="${IUSE} cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_arm_neon"
+IUSE="airplay alsa bluetooth bluray caps cec +css dbus doc eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical pipewire pulseaudio raspberry-pi samba system-ffmpeg test udf udev upnp vaapi vdpau wayland webserver X +xslt zeroconf ${CPU_FLAGS}"
 REQUIRED_USE="
 	${PYTHON_REQUIRED_USE}
-	|| ( gbm wayland X )
+	^^ ( gbm wayland X )
 	?? ( mariadb mysql )
 	bluray? ( udf )
+	gbm? ( udev )
 	udev? ( !libusb )
-	udisks? ( dbus )
-	upower? ( dbus )
-	power-control? ( dbus )
-	vdpau? (
-		X
-		!gles
-		!gbm
-	)
+	vdpau? ( X !gles !gbm )
 	zeroconf? ( dbus )
 "
 RESTRICT="!test? ( test )"
 
+# dev-libs/libcec[-cubox] bug #818262
 COMMON_DEPEND="
-	>=dev-libs/lzo-2.04
-	>=dev-libs/flatbuffers-1.11.0:=
-	>=dev-libs/tinyxml2-9.0.0:=
-	>=media-libs/libjpeg-turbo-2.1.4:=
+	>=dev-libs/flatbuffers-1.12.0:=
+	>=dev-libs/lzo-2.04:2
+	media-libs/giflib:=
+	>=media-libs/libjpeg-turbo-2.0.4:=
 	>=media-libs/libpng-1.6.26:0=
+	wayland? (
+		dev-cpp/waylandpp:=
+	)
 "
 COMMON_TARGET_DEPEND="${PYTHON_DEPS}
-	airplay? (
-		>=app-pda/libplist-2.0.0
-		net-libs/shairplay
-	)
-	alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
-	bluetooth? ( net-wireless/bluez )
-	bluray? ( >=media-libs/libbluray-1.3.2 )
-	caps? ( sys-libs/libcap )
-	dbus? ( sys-apps/dbus )
-	dev-db/sqlite
+	>=net-misc/curl-7.68.0[http2]
+	>=sys-libs/zlib-1.2.11
+	dev-db/sqlite:3
 	dev-libs/crossguid
 	>=dev-libs/fribidi-1.0.5
-	cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] )
+	>=dev-libs/libcdio-2.1.0:=[cxx]
+	>=dev-libs/libfmt-6.1.2:=
+	dev-libs/libfstrcmp
 	dev-libs/libpcre[cxx]
+	>=dev-libs/openssl-1.1.1k:0=
 	>=dev-libs/spdlog-1.5.0:=
 	dev-libs/tinyxml[stl]
+	dev-libs/tinyxml2:=
+	media-fonts/roboto
+	media-libs/libglvnd[X?]
+	>=media-libs/freetype-2.10.1
+	media-libs/harfbuzz:=
+	>=media-libs/libass-0.15.0:=
+	media-libs/mesa[egl(+),gbm(+)?,wayland?,X?]
+	>=media-libs/taglib-1.9.0
+	=media-video/ffmpeg-6*:=[encode,postproc,vaapi?,vdpau?,X?]
+	sci-libs/kissfft
+	virtual/libiconv
+	virtual/ttf-fonts
+	x11-libs/libdrm
 	$(python_gen_cond_dep '
 		dev-python/pillow[${PYTHON_USEDEP}]
 		dev-python/pycryptodome[${PYTHON_USEDEP}]
 	')
-	>=dev-libs/libcdio-2.1.0[cxx]
-	>=dev-libs/libfmt-9.1.0
-	dev-libs/libfstrcmp
+	airplay? (
+		>=app-pda/libplist-2.0.0:=
+		net-libs/shairplay
+	)
+	alsa? (
+		>=media-libs/alsa-lib-1.1.4.1
+	)
+	bluetooth? (
+		net-wireless/bluez:=
+	)
+	bluray? (
+		>=media-libs/libbluray-1.1.2:=
+	)
+	caps? (
+		sys-libs/libcap
+	)
+	cec? (
+		>=dev-libs/libcec-4.0[-cubox,raspberry-pi?]
+	)
+	dbus? (
+		sys-apps/dbus
+	)
 	gbm? (
-		>=dev-libs/libinput-1.10.5
-		media-libs/mesa[gbm(+)]
+		>=dev-libs/libinput-1.10.5:=
+		media-libs/libdisplay-info
 		x11-libs/libxkbcommon
 	)
 	gles? (
-		!raspberry-pi? ( media-libs/mesa[gles2] )
+		!raspberry-pi? (
+			media-libs/mesa[gles2]
+		)
+	)
+	!gles? (
+		media-libs/glu
+	)
+	lcms? (
+		>=media-libs/lcms-2.10:2
+	)
+	libusb? (
+		virtual/libusb:1
+	)
+	lirc? (
+		app-misc/lirc
+	)
+	mariadb? (
+		dev-db/mariadb-connector-c:=
+	)
+	mysql? (
+		dev-db/mysql-connector-c:=
+	)
+	nfs? (
+		>=net-fs/libnfs-2.0.0:=
+	)
+	pipewire? (
+		>=media-video/pipewire-0.3.50:=
+	)
+	pulseaudio? (
+		media-libs/libpulse
 	)
-	lcms? ( media-libs/lcms:2 )
-	libusb? ( virtual/libusb:1 )
-	virtual/ttf-fonts
-	media-fonts/roboto
-	>=media-libs/freetype-2.10.1
-	>=media-libs/libass-0.15.1
-	!raspberry-pi? ( media-libs/mesa[egl(+)] )
-	>=media-libs/taglib-1.11.1
-	system-ffmpeg? (
-		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[dav1d?,encode,postproc]
-		media-video/ffmpeg[openssl]
-	)
-	!system-ffmpeg? (
-		app-arch/bzip2
-		dav1d? ( media-libs/dav1d )
-	)
-	mysql? ( dev-db/mysql-connector-c:= )
-	mariadb? ( dev-db/mariadb-connector-c:= )
-	>=net-misc/curl-7.68.0[http2]
-	nfs? ( >=net-fs/libnfs-5.0.2:= )
-	!gles? ( media-libs/glu )
-	>=dev-libs/openssl-1.1.0:0=
 	raspberry-pi? (
-		|| ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl(+),gles2,video_cards_vc4] )
+		|| (
+			media-libs/raspberrypi-userland
+			media-libs/raspberrypi-userland-bin
+			media-libs/mesa[gles2,video_cards_vc4]
+		)
+	)
+	samba? (
+		>=net-fs/samba-3.4.6[smbclient(+)]
+	)
+	udf? (
+		>=dev-libs/libudfread-1.0.0
+	)
+	udev? (
+		virtual/libudev:=
 	)
-	pipewire? ( media-video/pipewire )
-	pulseaudio? ( media-libs/libpulse )
-	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
-	>=sys-libs/zlib-1.2.11
-	udf? ( >=dev-libs/libudfread-1.0.0 )
-	udev? ( virtual/udev )
 	vaapi? (
-		media-libs/libva:=
-		system-ffmpeg? ( media-video/ffmpeg[vaapi] )
-		wayland? ( media-libs/libva[wayland] )
-		X? ( media-libs/libva[X] )
+		media-libs/libva:=[wayland?,X?]
 	)
-	virtual/libiconv
 	vdpau? (
-		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
-		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
+		|| (
+			>=x11-libs/libvdpau-1.1
+			>=x11-drivers/nvidia-drivers-180.51
+		)
 	)
 	wayland? (
-		>=dev-cpp/waylandpp-0.2.3:=
-		media-libs/mesa[wayland]
-		>=dev-libs/wayland-protocols-1.7
-		>=x11-libs/libxkbcommon-0.4.1
+		>=x11-libs/libxkbcommon-0.4.1[wayland]
+	)
+	webserver? (
+		>=net-libs/libmicrohttpd-0.9.55:=[messages(+)]
 	)
-	webserver? ( >=net-libs/libmicrohttpd-0.9.75:=[messages(+)] )
 	X? (
-		media-libs/mesa[X]
-		!gles? ( media-libs/libglvnd[X] )
 		x11-libs/libX11
+		x11-libs/libXext
 		x11-libs/libXrandr
-		x11-libs/libXrender
-		system-ffmpeg? ( media-video/ffmpeg[X] )
 	)
-	x11-libs/libdrm
 	xslt? (
 		dev-libs/libxslt
-		>=dev-libs/libxml2-2.10.1
+		>=dev-libs/libxml2-2.9.4
+	)
+	zeroconf? (
+		net-dns/avahi[dbus]
 	)
-	zeroconf? ( net-dns/avahi[dbus] )
 "
-RDEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
-	lirc? ( app-misc/lirc )
-	power-control? ( || ( sys-apps/systemd sys-auth/elogind ) )
-	udisks? ( sys-fs/udisks:2 )
-	upower? ( sys-power/upower )
+RDEPEND="
+	${COMMON_DEPEND}
+	${COMMON_TARGET_DEPEND}
 "
-DEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
-	dev-libs/rapidjson
-	test? ( >=dev-cpp/gtest-1.10.0 )
+DEPEND="
+	${COMMON_DEPEND}
+	${COMMON_TARGET_DEPEND}
+	>=dev-libs/rapidjson-1.0.2
+	test? (
+		>=dev-cpp/gtest-1.10.0
+	)
+	wayland? (
+		>=dev-libs/wayland-protocols-1.7
+	)
+	X? (
+		x11-base/xorg-proto
+		x11-libs/libXrender
+	)
 "
-BDEPEND="${COMMON_DEPEND}
+BDEPEND="
+	${COMMON_DEPEND}
+	app-arch/unzip
 	dev-build/cmake
 	dev-lang/swig
-	media-libs/giflib
-	>=dev-libs/flatbuffers-1.11.0
-	>=media-libs/libjpeg-turbo-2.0.4:=
-	>=media-libs/libpng-1.6.26:0=
 	virtual/pkgconfig
-	virtual/jre
+	<=virtual/jre-17:*
+	doc? (
+		app-text/doxygen
+	)
 "
 
+# bug #544020
 CONFIG_CHECK="~IP_MULTICAST"
 ERROR_IP_MULTICAST="
 In some cases Kodi needs to access multicast addresses.
@@ -191,6 +268,7 @@ Please consider enabling IP_MULTICAST under Networking options.
 
 pkg_setup() {
 	check_extra_config
+	java-pkg-2_pkg_setup
 	python-single-r1_pkg_setup
 }
 
@@ -198,7 +276,7 @@ src_unpack() {
 	if [[ ${PV} == *9999 ]] ; then
 		git-r3_src_unpack
 	else
-		default
+		unpack ${MY_P}.tar.gz
 	fi
 }
 
@@ -210,70 +288,69 @@ src_prepare() {
 		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
 		xbmc/platform/linux/*.cpp || die
 
-	# Prepare tools and libs witch are configured with autotools during compile time
-	AUTOTOOLS_DIRS=(
-		"${S}"/tools/depends/native/TexturePacker/src
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src
-	)
-
-	local d
-	for d in "${AUTOTOOLS_DIRS[@]}" ; do
-		pushd ${d} >/dev/null || die
-		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
-		popd >/dev/null || die
+	# Add all possible names for kissfft libraries
+	for datatype in {float,int16,int32,simd}; do
+		sed -i \
+			-e "s/\(find_library(KISSFFT_LIBRARY NAMES .*\)/\1 kissfft-${datatype} kissfft-${datatype}-openmp/" \
+			cmake/modules/FindKissFFT.cmake || die
 	done
-	elibtoolize
 
-	# Prevent autoreconf rerun
-	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
-		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
-		|| die
+	if tc-is-cross-compiler; then
+		# These tools are automatically built with CMake during a native build
+		# but need to be built in advance using Autotools for a cross build.
+		NATIVE_TOOLS=(
+			TexturePacker
+			JsonSchemaBuilder
+		)
+
+		local t
+		for t in "${NATIVE_TOOLS[@]}" ; do
+			pushd "${S}/tools/depends/native/$t/src" >/dev/null || die
+			AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
+			popd >/dev/null || die
+		done
+		elibtoolize
+	fi
 }
 
 src_configure() {
-	local platform=()
-	use gbm && platform+=( gbm )
-	use wayland && platform+=( wayland )
-	use X && platform+=( x11 )
-	local core_platform_name="${platform[@]}"
 	local mycmakeargs=(
-		-DENABLE_SSE=$(usex cpu_flags_x86_sse)
-		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
-		-DENABLE_SSE3=$(usex cpu_flags_x86_sse3)
-		-DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1)
-		-DENABLE_SSE4_2=$(usex cpu_flags_x86_sse4_2)
-		-DENABLE_AVX=$(usex cpu_flags_x86_avx)
-		-DENABLE_AVX2=$(usex cpu_flags_x86_avx2)
-		-DENABLE_NEON=$(usex cpu_flags_arm_neon)
+		-Wno-dev # less noise
+
+		-DAPP_RENDER_SYSTEM=$(usex gles gles gl)
+		-DCORE_PLATFORM_NAME=$(usev gbm)$(usev wayland)$(usev X x11)
 		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+		-DENABLE_TESTING=$(usex test)
 		-DVERBOSE=ON
-		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
-		-DENABLE_ALSA=$(usex alsa)
-		-DENABLE_AIRTUNES=$(usex airplay)
-		-DENABLE_AVAHI=$(usex zeroconf)
-		-DENABLE_BLUETOOTH=$(usex bluetooth)
-		-DENABLE_BLURAY=$(usex bluray)
+
+		# Enforce use of configured python interpeter
+		-DPYTHON_PATH=$(python_get_library_path)
+		-DPYTHON_VER=${EPYTHON##python} # wont work for pypy
+
+		# Toolchain
 		-DENABLE_CCACHE=OFF
 		-DENABLE_CLANGFORMAT=OFF
 		-DENABLE_CLANGTIDY=OFF
 		-DENABLE_CPPCHECK=OFF
-		-DENABLE_ISO9660PP=$(usex optical)
+		-DENABLE_INCLUDEWHATYOUUSE=OFF
+		# https://bugs.gentoo.org/show_bug.cgi?id=606124
+		-DENABLE_GOLD=OFF
+		-DENABLE_LLD=OFF
+		-DENABLE_MOLD=OFF
+		-DUSE_LTO=OFF
+
+		# Features
+		-DENABLE_AIRTUNES=$(usex airplay)
+		-DENABLE_ALSA=$(usex alsa)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_BLUETOOTH=$(usex bluetooth)
+		-DENABLE_BLURAY=$(usex bluray)
+		-DENABLE_CAP=$(usex caps)
 		-DENABLE_CEC=$(usex cec)
 		-DENABLE_DBUS=$(usex dbus)
 		-DENABLE_DVDCSS=$(usex css)
 		-DENABLE_EVENTCLIENTS=ON # alway enable to have 'kodi-send' and filter extra staff in 'src_install()'
-		-DENABLE_INTERNAL_CROSSGUID=OFF
-		-DENABLE_INTERNAL_RapidJSON=OFF
-		-DENABLE_INTERNAL_FMT=OFF
-		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
-		-DENABLE_INTERNAL_FSTRCMP=OFF
-		-DENABLE_INTERNAL_FLATBUFFERS=OFF
-		-DENABLE_INTERNAL_DAV1D=OFF
-		-DENABLE_INTERNAL_GTEST=OFF
-		-DENABLE_INTERNAL_UDFREAD=OFF
-		-DENABLE_INTERNAL_SPDLOG=OFF
-		-DENABLE_CAP=$(usex caps)
+		-DENABLE_ISO9660PP=$(usex optical)
 		-DENABLE_LCMS2=$(usex lcms)
 		-DENABLE_LIRCCLIENT=$(usex lirc)
 		-DENABLE_MARIADBCLIENT=$(usex mariadb)
@@ -281,65 +358,96 @@ src_configure() {
 		-DENABLE_MICROHTTPD=$(usex webserver)
 		-DENABLE_MYSQLCLIENT=$(usex mysql)
 		-DENABLE_NFS=$(usex nfs)
-		-DENABLE_OPENGLES=$(usex gles)
 		-DENABLE_OPENGL=$(usex !gles)
+		-DENABLE_OPENGLES=$(usex gles)
 		-DENABLE_OPTICAL=$(usex optical)
-		-DENABLE_PLIST=$(usex airplay)
 		-DENABLE_PIPEWIRE=$(usex pipewire)
+		-DENABLE_PLIST=$(usex airplay)
 		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
 		-DENABLE_SMBCLIENT=$(usex samba)
 		-DENABLE_SNDIO=OFF
-		-DENABLE_TESTING=$(usex test)
 		-DENABLE_UDEV=$(usex udev)
 		-DENABLE_UDFREAD=$(usex udf)
 		-DENABLE_UPNP=$(usex upnp)
 		-DENABLE_VAAPI=$(usex vaapi)
 		-DENABLE_VDPAU=$(usex vdpau)
 		-DENABLE_XSLT=$(usex xslt)
-		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
+
+		#To bundle or not
+		-DENABLE_INTERNAL_CEC=OFF
+		-DENABLE_INTERNAL_CROSSGUID=OFF
+		-DENABLE_INTERNAL_DAV1D=OFF
+		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
+		-DENABLE_INTERNAL_FLATBUFFERS=OFF
+		-DENABLE_INTERNAL_FMT=OFF
+		-DENABLE_INTERNAL_FSTRCMP=OFF
+		-DENABLE_INTERNAL_GTEST=OFF
+		-DENABLE_INTERNAL_KISSFFT=OFF
+		-DENABLE_INTERNAL_PCRE=OFF
+		-DENABLE_INTERNAL_RapidJSON=OFF
+		-DENABLE_INTERNAL_SPDLOG=OFF
+		-DENABLE_INTERNAL_TAGLIB=OFF
+		-DENABLE_INTERNAL_UDFREAD=OFF
+
+		-DTARBALL_DIR="${DISTDIR}"
 		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
-		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
-		-DPYTHON_VER="${EPYTHON#python}"
-		-DAPP_RENDER_SYSTEM="$(usex gles gles gl)"
-		-DCORE_PLATFORM_NAME="${core_platform_name}"
+		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
 	)
 
+	# Separated to avoid "Manually-specified variables were not used by the project:"
+	use css && mycmakeargs+=( -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz" )
+	use nfs && mycmakeargs+=( -DENABLE_INTERNAL_NFS=OFF )
 	use !udev && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
-
 	use X && use !gles && mycmakeargs+=( -DENABLE_GLX=ON )
 
-	if use system-ffmpeg; then
-		mycmakeargs+=( -DWITH_FFMPEG="yes" )
-	else
-		mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
-	fi
+	for flag in ${CPU_FLAGS[@]} ; do
+		local name=${flag#cpu_flags_*_}
+		mycmakeargs+=( -DENABLE_${name^^}=$(usex ${flag}) )
+	done
 
-	if ! echo "${CFLAGS}" | grep -Fwqe '-DNDEBUG' - && ! echo "${CFLAGS}" | grep -Fwqe '-D_DEBUG' - ; then
-		CFLAGS+=' -DNDEBUG' # Kodi requires one of the 'NDEBUG' or '_DEBUG' defines
-		CXXFLAGS+=' -DNDEBUG'
+	if ! is-flag -DNDEBUG && ! is-flag -D_DEBUG ; then
+		# Kodi requires one of the 'NDEBUG' or '_DEBUG' defines
+		append-cflags -DNDEBUG
+		append-cxxflags -DNDEBUG
 	fi
 
+	# Violates ODR (bug #860984) and USE_LTO does spooky stuff
+	# https://github.com/xbmc/xbmc/commit/cb72a22d54a91845b1092c295f84eeb48328921e
+	filter-lto
+
 	cmake_src_configure
 }
 
 src_compile() {
 	cmake_src_compile all
+	use doc && cmake_build doc
+	use test && cmake_build kodi-test
 }
 
 src_test() {
-	local myctestargs=(
+	local -x CMAKE_SKIP_TESTS=(
 		# Known failing, unreliable test
 		# bug #743938
-		-E "(TestCPUInfo.GetCPUFrequency)"
+		TestCPUInfo.GetCPUFrequency
+		# Test failure stemming from sci-libs/kissfft
+		# The difference between output[2i] and (i==freq1?1.0:0.0) is inf, which exceeds 1e-7, where output[2i]
+		# evaluates to inf,(i==freq1?1.0:0.0) evaluates to 0, and 1e-7 evaluates to 9.9999999999999995e-08.
+		TestRFFT.SimpleSignal
+		# bug #779184
+		# https://github.com/xbmc/xbmc/issues/18594
+		$(usev x86 TestDateTime.SetFromDBTime)
 	)
 
 	# see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213
-	KODI_HOME="${BUILD_DIR}" cmake_build check
+	local -x KODI_HOME="${BUILD_DIR}"
+
+	cmake_src_test
 }
 
 src_install() {
 	cmake_src_install
 
+	# bug #457588
 	pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
 
 	newicon media/icon48x48.png kodi.png
@@ -357,4 +465,17 @@ src_install() {
 	fi
 
 	python_optimize "${D}$(python_get_sitedir)"
+
+	einstalldocs
+	use doc && dodoc -r "${S}"/docs/html/
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use dbus ; then
+		optfeature "getting battery level and active power source" sys-power/upower
+		optfeature "control of shutdown, reboot, suspend, and hibernate" sys-auth/elogind sys-apps/systemd
+		optfeature "storage management support (automounting, volume monitoring, etc)" sys-fs/udisks:2
+	fi
 }