proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 72 insertions, 0 deletions

diff --git a/media-video/mjpg-streamer/mjpg-streamer-0_pre20120421.ebuild b/media-video/mjpg-streamer/mjpg-streamer-0_pre20120421.ebuild
new file mode 100644
index 000000000000..2e1db0993aa3
--- /dev/null
+++ b/media-video/mjpg-streamer/mjpg-streamer-0_pre20120421.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit eutils
+
+DESCRIPTION="MJPG-streamer takes JPGs from Linux-UVC compatible webcams"
+HOMEPAGE="http://sourceforge.net/projects/mjpg-streamer"
+SRC_URI="http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+
+INPUT_PLUGINS="input_testpicture input_control input_file input_uvc"
+OUTPUT_PLUGINS="output_file output_udp output_http output_autofocus output_rtsp"
+IUSE_PLUGINS="${INPUT_PLUGINS} ${OUTPUT_PLUGINS} +input_file +output_http"
+IUSE="${IUSE_PLUGINS} www v4l"
+REQUIRED_USE="|| ( ${INPUT_PLUGINS} )
+	|| ( ${OUTPUT_PLUGINS} )
+	v4l? ( input_uvc )"
+
+RDEPEND="virtual/jpeg
+	v4l? ( input_uvc? ( media-libs/libv4l ) )"
+DEPEND="${RDEPEND}
+	input_testpicture? ( media-gfx/imagemagick )"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PV}-make-var-instead-of-cmd.patch"
+
+	local flag switch
+
+	for flag in ${IUSE_PLUGINS}; do
+		use ${flag} && switch='' || switch='#'
+		sed -i \
+			-e "s|^#*PLUGINS +\?= ${flag}.so|${switch}PLUGINS += ${flag}.so|" \
+			Makefile
+	done
+}
+
+src_compile() {
+	local v4l=$(use v4l && use input_uvc && echo 'USE_LIBV4L2=true')
+	emake ${v4l}
+}
+
+src_install() {
+	into /usr
+	dobin ${PN//-/_}
+	dolib.so *.so
+
+	if use www ; then
+		insinto /usr/share/${PN}
+		doins -r www
+	fi
+
+	dodoc README TODO
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}
+
+pkg_postinst() {
+	elog "Remember to set an input and output plugin for mjpg-streamer."
+
+	if use www ; then
+		echo
+		elog "An example webinterface has been installed into"
+		elog "/usr/share/mjpg-streamer/www for your usage."
+	fi
+}