net-analyzer/netdata: openrc and systemd fixes

Create the var/cache/netdata directory if it doesn't already exist in the systemd script
Fix the path to the netdata executable in the openrc script
Eliminate bashisms in openrc script

Gentoo-bug: 633380
Package-Manager: Portage-2.3.11, Repoman-2.3.3

1 files changed, 108 insertions, 0 deletions

diff --git a/net-analyzer/netdata/netdata-1.8.0-r1.ebuild b/net-analyzer/netdata/netdata-1.8.0-r1.ebuild
new file mode 100644
index 000000000000..d23f3237e7b5
--- /dev/null
+++ b/net-analyzer/netdata/netdata-1.8.0-r1.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit autotools fcaps linux-info python-r1 systemd user
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/firehol/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/firehol/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Linux real time system monitoring, done right!"
+HOMEPAGE="https://github.com/firehol/netdata https://my-netdata.io/"
+PATCHES=( "${FILESDIR}/${P}-openrc-fixes.patch" )
+
+LICENSE="GPL-3+ MIT BSD"
+SLOT="0"
+IUSE="caps +compression cpu_flags_x86_sse2 ipmi mysql nfacct nodejs postgres +python"
+REQUIRED_USE="
+	mysql? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+# most unconditional dependencies are for plugins.d/charts.d.plugin:
+RDEPEND="
+	>=app-shells/bash-4:0
+	|| (
+		net-analyzer/netcat6
+		net-analyzer/netcat
+	)
+	net-analyzer/tcpdump
+	net-analyzer/traceroute
+	net-misc/curl
+	net-misc/wget
+	sys-apps/util-linux
+	virtual/awk
+	caps? ( sys-libs/libcap )
+	compression? ( sys-libs/zlib )
+	ipmi? ( sys-libs/freeipmi )
+	nfacct? (
+		net-firewall/nfacct
+		net-libs/libmnl
+	)
+	nodejs? ( net-libs/nodejs )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		mysql? (
+			|| (
+				dev-python/mysqlclient[${PYTHON_USEDEP}]
+				dev-python/mysql-python[${PYTHON_USEDEP}]
+			)
+		)
+		postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+: ${NETDATA_USER:=netdata}
+: ${NETDATA_GROUP:=netdata}
+
+FILECAPS=(
+	'cap_dac_read_search,cap_sys_ptrace+ep' 'usr/libexec/netdata/plugins.d/apps.plugin'
+)
+
+pkg_setup() {
+	linux-info_pkg_setup
+
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 / ${PN}
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir="${EPREFIX}"/var \
+		--with-user=${NETDATA_USER} \
+		$(use_enable nfacct plugin-nfacct) \
+		$(use_enable ipmi plugin-freeipmi) \
+		$(use_enable cpu_flags_x86_sse2 x86-sse) \
+		$(use_with compression zlib)
+}
+
+src_install() {
+	default
+
+	rm -rf "${D}/var/cache/netdata" || die
+
+	# Remove unneeded .keep files
+	find "${ED}" -name ".keep" -delete || die
+
+	fowners -Rc ${NETDATA_USER}:${NETDATA_GROUP} /var/log/netdata
+	fowners -Rc ${NETDATA_USER}:${NETDATA_GROUP} /var/lib/netdata
+
+	fowners -Rc root:${NETDATA_GROUP} /usr/share/${PN}
+
+	newinitd system/netdata-openrc ${PN}
+	systemd_dounit system/netdata.service
+	insinto /etc/netdata
+	doins system/netdata.conf
+}