net-analyzer/openvas-libraries: Version Bump

fixes gnutls-3 support and compilation problems

Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=544664
Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=555544
Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=556788

Package-Manager: portage-2.2.25
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/net-analyzer/openvas-libraries/openvas-libraries-8.0.5.ebuild b/net-analyzer/openvas-libraries/openvas-libraries-8.0.5.ebuild
new file mode 100644
index 000000000000..6e7215bcb44f
--- /dev/null
+++ b/net-analyzer/openvas-libraries/openvas-libraries-8.0.5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+DL_ID=2191
+
+DESCRIPTION="A remote security scanner for Linux (openvas-libraries)"
+HOMEPAGE="http://www.openvas.org/"
+SRC_URI="http://wald.intevation.org/frs/download.php/${DL_ID}/${P/_beta/+beta}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="ldap"
+
+RDEPEND="
+	app-crypt/gpgme
+	>=dev-libs/glib-2.16
+	>=dev-libs/hiredis-0.10.1
+	dev-libs/libgcrypt:0
+	dev-libs/libksba
+	!net-analyzer/openvas-libnasl
+	net-libs/gnutls
+	net-libs/libpcap
+	>=net-libs/libssh-0.5.0
+	net-analyzer/net-snmp
+	ldap? (	net-nds/openldap )"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	"
+
+S="${WORKDIR}"/${P}
+
+DOCS=( ChangeLog CHANGES README )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-7.0.4-libssh.patch
+	"${FILESDIR}"/${PN}-8.0.1-include.patch
+	"${FILESDIR}"/${P}-underlinking.patch
+	)
+
+src_prepare() {
+	sed \
+		-e '/^install.*OPENVAS_CACHE_DIR.*/d' \
+		-i CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOCALSTATEDIR=${EPREFIX}/var"
+		"-DSYSCONFDIR=${EPREFIX}/etc"
+		$(usex ldap -DBUILD_WITHOUT_LDAP=0 -DBUILD_WITHOUT_LDAP=1)
+	)
+	cmake-utils_src_configure
+}