net-fs/mc: Version bump

Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
RepoMan-Options: --ignore-arches

1 files changed, 49 insertions, 0 deletions

diff --git a/net-fs/mc/mc-2019.02.06.20.26.56.ebuild b/net-fs/mc/mc-2019.02.06.20.26.56.ebuild
new file mode 100644
index 000000000000..7a3a66e507b5
--- /dev/null
+++ b/net-fs/mc/mc-2019.02.06.20.26.56.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eapi7-ver bash-completion-r1 golang-build golang-vcs-snapshot
+
+MY_PV="$(ver_cut 1-3)T$(ver_cut 4-7)Z"
+MY_PV=${MY_PV//./-}
+
+EGIT_COMMIT="c352cadd4be2c6bed64884c78d1e8a8ac6efaf3f"
+
+EGO_PN="github.com/minio/mc"
+
+DESCRIPTION="Minio client provides alternatives for ls, cat on cloud storage and filesystems"
+HOMEPAGE="https://github.com/minio/mc"
+SRC_URI="https://${EGO_PN}/archive/RELEASE.${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="!!app-misc/mc"
+
+src_prepare() {
+	default
+	sed -i -e "s/time.Now().UTC().Format(time.RFC3339)/\"${VERSION}\"/"\
+		-e "s/-s //"\
+		-e "/time/d"\
+		-e "s/+ commitID()/+ \"${EGIT_COMMIT}\"/"\
+		src/${EGO_PN}/buildscripts/gen-ldflags.go || die
+
+}
+
+src_compile() {
+	pushd src/${EGO_PN} || die
+	MC_RELEASE="${MY_PV}"
+	GOPATH="${S}" go build --ldflags "$(go run buildscripts/gen-ldflags.go)" -o ${PN} || die
+	popd || die
+
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dodoc -r README.md CONTRIBUTING.md docs
+	dobin mc
+	newbashcomp autocomplete/bash_autocomplete ${PN}
+	popd  || die
+}