net-im/telegram-desktop-bin: bump to 1.3.10 and disable auto-updates

This version bump uses a new upstream feature to tell the binary that it
should not check for updates itself. The ebuild installs the binary to
/usr/lib/ and deploys a wrapper to /usr/bin/.

Closes: https://bugs.gentoo.org/618662
Closes: https://github.com/gentoo/gentoo/pull/9218
Signed-off-by: Henning Schild <henning@hennsch.de>
Signed-off-by: NP-Hardass <NP-Hardass@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/net-im/telegram-desktop-bin/telegram-desktop-bin-1.3.10.ebuild b/net-im/telegram-desktop-bin/telegram-desktop-bin-1.3.10.ebuild
new file mode 100644
index 000000000000..d55f48e2ac53
--- /dev/null
+++ b/net-im/telegram-desktop-bin/telegram-desktop-bin-1.3.10.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit desktop gnome2-utils xdg
+
+DESCRIPTION="Official desktop client for Telegram (binary package)"
+HOMEPAGE="https://desktop.telegram.org"
+SRC_URI="
+	https://github.com/telegramdesktop/tdesktop/archive/v${PV}.tar.gz -> tdesktop-${PV}.tar.gz
+	amd64? ( https://updates.tdesktop.com/tlinux/tsetup.${PV}.tar.xz )
+	x86? ( https://updates.tdesktop.com/tlinux32/tsetup32.${PV}.tar.xz )
+"
+
+LICENSE="telegram"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+QA_PREBUILT="usr/lib/${PN}/bin/${PN}"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=sys-apps/dbus-1.4.20
+	x11-libs/libX11
+	>=x11-libs/libxcb-1.10[xkb]
+"
+
+S="${WORKDIR}/Telegram"
+
+src_install() {
+	into /usr/lib/${PN}
+	newbin "${S}/Telegram" ${PN}
+	into /usr
+	newbin  "${FILESDIR}"/${PN} "telegram-desktop"
+
+	local icon_size
+	for icon_size in 16 32 48 64 128 256 512; do
+		newicon -s "${icon_size}" \
+			"${WORKDIR}/tdesktop-${PV}/Telegram/Resources/art/icon${icon_size}.png" \
+			telegram-desktop.png
+	done
+
+	domenu "${WORKDIR}/tdesktop-${PV}"/lib/xdg/telegramdesktop.desktop
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_icon_cache_update
+}