net-im/telegram-desktop-bin: version bump to 1.5.12.

Signed-off-by: Henning Schild <henning@hennsch.de>
Closes: https://github.com/gentoo/gentoo/pull/11015
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

1 files changed, 65 insertions, 0 deletions

diff --git a/net-im/telegram-desktop-bin/telegram-desktop-bin-1.5.12.ebuild b/net-im/telegram-desktop-bin/telegram-desktop-bin-1.5.12.ebuild
new file mode 100644
index 000000000000..10f3a4e22b72
--- /dev/null
+++ b/net-im/telegram-desktop-bin/telegram-desktop-bin-1.5.12.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit desktop gnome2-utils xdg
+
+DESCRIPTION="Official desktop client for Telegram (binary package)"
+HOMEPAGE="https://desktop.telegram.org"
+SRC_URI="
+	https://github.com/telegramdesktop/tdesktop/archive/v${PV}.tar.gz -> tdesktop-${PV}.tar.gz
+	amd64? ( https://github.com/telegramdesktop/tdesktop/releases/download/v${PV}/tsetup.${PV}.tar.xz )
+	x86? ( https://github.com/telegramdesktop/tdesktop/releases/download/v${PV}/tsetup32.${PV}.tar.xz )
+"
+
+LICENSE="telegram"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+
+QA_PREBUILT="usr/lib/${PN}/Telegram"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=sys-apps/dbus-1.4.20
+	x11-libs/libX11
+	>=x11-libs/libxcb-1.10[xkb]
+	>=media-libs/fontconfig-2.13
+"
+
+S="${WORKDIR}/Telegram"
+
+src_install() {
+	exeinto /usr/lib/${PN}
+	doexe "Telegram"
+	newbin "${FILESDIR}"/${PN} "telegram-desktop"
+
+	local icon_size
+	for icon_size in 16 32 48 64 128 256 512; do
+		newicon -s "${icon_size}" \
+			"${WORKDIR}/tdesktop-${PV}/Telegram/Resources/art/icon${icon_size}.png" \
+			telegram.png
+	done
+
+	domenu "${WORKDIR}/tdesktop-${PV}"/lib/xdg/telegramdesktop.desktop
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_icon_cache_update
+	einfo
+	einfo "Previous versions of ${PN} have created "
+	einfo "\"~/.local/share/applications/telegram.desktop\". These files"
+	einfo "conflict with the one shipped by portage and should be removed"
+	einfo "from all homedirs. (https://bugs.gentoo.org/618662)"
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_icon_cache_update
+}