net-libs/cvm: drop 0.96-r1

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 0 insertions, 124 deletions

diff --git a/net-libs/cvm/Manifest b/net-libs/cvm/Manifest
index 47589513a49f..3c2c7a723e66 100644
--- a/net-libs/cvm/Manifest
+++ b/net-libs/cvm/Manifest
@@ -1,2 +1 @@
-DIST cvm-0.96.tar.gz 127999 BLAKE2B bf6a0f26538f4f10dafe9d021e6f3ef22ee57230f64cf50cba95be3cb5ddf54a0479d033936d26ee9526745ead61fc6af7bfd1fdc3da10a6915108b2d873772c SHA512 23adf39571bf414fa61084ac824a54b3cb37ef32a46c72ad50734743fb66bb923168eb866d72fba7f88397b37831e2ce7603c7d543996b28761ed1d5b053d73d
 DIST cvm-0.97.tar.gz 127759 BLAKE2B 857a30ae52e7edc5e8bc66dfbe7e2ada6ba7763260b073eabbca6ee289b68ceece92442dffc5aa1d358faec24f90993d88d3555dd9399837f25e9f689ab6d66b SHA512 b04ca9edb8c84e06628ed1a827d28bf7d787c3853bec1e064fc1eb7e3082ad81998e7c902e029c0f01c346a52a4419e3c9890e2a7a75ab38625e0078dc4e9891
diff --git a/net-libs/cvm/cvm-0.96-r1.ebuild b/net-libs/cvm/cvm-0.96-r1.ebuild
deleted file mode 100644
index 4f150585b773..000000000000
--- a/net-libs/cvm/cvm-0.96-r1.ebuild
+++ /dev/null
@@ -1,123 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit toolchain-funcs
-
-DESCRIPTION="Credential Validation Modules by Bruce Guenter"
-HOMEPAGE="http://untroubled.org/cvm/"
-SRC_URI="http://untroubled.org/cvm/archive/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ppc ~sparc ~x86"
-IUSE="mysql postgres test vpopmail"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-db/cdb:=
-	>=dev-libs/bglibs-1.041:="
-DEPEND="${RDEPEND}
-	mysql? ( dev-db/mysql-connector-c:0= )
-	postgres? ( dev-db/postgresql[server] )
-	vpopmail? ( net-mail/vpopmail )
-	test? (
-		app-editors/vim
-		dev-db/sqlite
-	)"
-# some of the testcases use
-# - ex/vi/xxd
-# - cdbmake
-# - sqlite
-
-PATCHES=( "${FILESDIR}"/${PN}-0.96-fix-test-padding.patch )
-
-src_prepare() {
-	default
-	# disable this test, as it breaks under Portage
-	# and there is no easy fix
-	sed -i.orig \
-		-e '/qmail-lookup-nodomain/,/^END_OF_TEST_RESULTS/d' \
-		"${S}"/tests.sh || die "sed failed"
-	# Fix the vpopmail build
-	sed -i.orig \
-		-e '/.\/ltload cvm-vchkpw/s,-lmysqlclient,,g' \
-		-e '/.\/ltload cvm-vchkpw/s,-L/usr/local/vpopmail/lib,,g' \
-		-e '/.\/ltload cvm-vchkpw/s,-L/var/vpopmail/lib,,g' \
-		-e '/.\/ltload cvm-vchkpw/s,-L/usr/local/lib/mysql,,g' \
-		-e '/.\/ltload cvm-vchkpw/s,\.la,.la `cat /var/vpopmail/etc/lib_deps`,g' \
-		"${S}"/Makefile \
-		|| die "Failed to fix vpopmail linking parts of Makefile"
-	sed -i.orig \
-		-e '/.\/compile cvm-vchkpw/s,$, `cat /var/vpopmail/etc/inc_deps`,g' \
-		"${S}"/Makefile \
-		|| die "Failed to fix vpopmail compiling parts of Makefile"
-}
-
-src_configure() {
-	echo "/usr/include/bglibs" > conf-bgincs || die
-	echo "/usr/$(get_libdir)/bglibs" > conf-bglibs || die
-	echo "/usr/include" > conf-include || die
-	echo "/usr/$(get_libdir)" > conf-lib || die
-	echo "/usr/bin" > conf-bin || die
-	echo "$(tc-getCC) ${CFLAGS}" > conf-cc || die
-	echo "$(tc-getCC) ${LDFLAGS} -lcrypt" > conf-ld || die
-}
-
-src_compile() {
-	emake -j1
-
-	if use mysql; then
-		einfo "Building MySQL support"
-		emake -j1 mysql
-	fi
-
-	if use postgres; then
-		einfo "Building Postgresql support"
-		emake -j1 pgsql
-	fi
-
-	if use vpopmail; then
-		einfo "Building vpopmail support"
-		emake -j1 cvm-vchkpw
-	fi
-}
-
-src_test() {
-	# bug 624384
-	# the test suite tests stuff that isn't potentially enabled
-	emake -j1 sqlite
-	sh tests.sh || die "Testing Failed"
-}
-
-src_install() {
-	# Upstreams installer is incredibly broken
-	dolib.a .libs/*.a
-	dolib.so .libs/*.so.*
-
-	local i
-	for i in a so; do
-		dosym libcvm-v2client.${i} /usr/$(get_libdir)/libcvm-client.${i}
-	done
-
-	for i in {bench,test}client chain checkpassword pwfile qmail unix \
-			vmailmgr{,-local,-udp} v1{benchclient,checkpassword,testclient} \
-		; do
-			dobin .libs/cvm-${i}
-	done
-	use mysql && dobin .libs/cvm-mysql{,-local,-udp}
-	use postgres && dobin .libs/cvm-pgsql{,-local,-udp}
-	use vpopmail && dobin .libs/cvm-vchkpw
-
-	insinto /usr/include/cvm
-	doins {credentials,errors,facts,module,protocol,sasl,v1client,v2client}.h
-	dosym v1client.h /usr/include/cvm/client.h
-	dosym cvm/sasl.h /usr/include/cvm-sasl.h
-
-	dodoc ANNOUNCEMENT NEWS{,.sql,.vmailmgr}
-	dodoc README{,.vchkpw,.vmailmgr}
-	dodoc TODO VERSION ChangeLog*
-	docinto html
-	dodoc *.html
-}