proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 54 insertions, 0 deletions

diff --git a/net-libs/libgsasl/libgsasl-1.8.0-r1.ebuild b/net-libs/libgsasl/libgsasl-1.8.0-r1.ebuild
new file mode 100644
index 000000000000..c7db36782bf3
--- /dev/null
+++ b/net-libs/libgsasl/libgsasl-1.8.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+inherit autotools eutils
+
+DESCRIPTION="The GNU SASL library"
+HOMEPAGE="http://www.gnu.org/software/gsasl/"
+SRC_URI="mirror://gnu/${PN/lib}/${P}.tar.gz"
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="idn gcrypt kerberos nls ntlm static-libs"
+DEPEND="
+	gcrypt? ( dev-libs/libgcrypt:0 )
+	idn? ( net-dns/libidn )
+	kerberos? ( virtual/krb5 )
+	nls? ( >=sys-devel/gettext-0.18.1 )
+	ntlm? ( net-libs/libntlm )
+"
+RDEPEND="${DEPEND}
+	!net-misc/gsasl"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-gss-extra.patch"
+	sed -i -e 's/ -Werror//' configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local krb5_impl
+	if use kerberos; then
+		krb5_impl="--with-gssapi-impl="
+		krb5_impl+=$(has_version app-crypt/mit-krb5 && echo "mit" || echo "heimdal")
+	fi
+	econf \
+		$(use_with gcrypt libgcrypt) \
+		$(use_with idn stringprep) \
+		$(use_enable kerberos gssapi) \
+		${krb5_impl} \
+		$(use_enable nls) \
+		$(use_enable ntlm) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	if ! use static-libs; then
+		rm -f "${D}"/usr/lib*/lib*.la
+	fi
+}