net-libs/libwebsockets: Version bump to 4.2.2

Signed-off-by: Luka Perkov <luka.perkov@sartura.hr>
Signed-off-by: Jakov Smolić <jsmolic@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/net-libs/libwebsockets/Manifest b/net-libs/libwebsockets/Manifest
index 4fee651581a5..f65b52f900be 100644
--- a/net-libs/libwebsockets/Manifest
+++ b/net-libs/libwebsockets/Manifest
@@ -1,2 +1,3 @@
 DIST libwebsockets-4.2.0.tar.gz 14550541 BLAKE2B 9471d19b15decfee4407a596cb3f127534e12ac6bf49c81b04120a379ff8a8e1c7767e9a7e586ad69d5af23e869914c749da771f8db6431ac09718b971d261e0 SHA512 e1fb5b204a030ded8dfe2a75c66ec8d1a2e6a67e82c7709fe3c4277e0ccb5fb40c18db04e73c640d07ef4516aa266ae8b102f802b2a41b80980260cb6921f369
 DIST libwebsockets-4.2.1.tar.gz 14557242 BLAKE2B 07d5a7278a3f0518f8d8c1a20c6ad08d7125c276d1b0236649abe961879e3985319ce03d6800f7312f63d2a92dd96d341783257695a91864a2ee93116a5a108f SHA512 b8b03a9f099079aace448eeee6690bee519c23ba14e0b186e1813bfdb9b915462a07a5f52bdb81949021bf631d99bda2661704814575f559b5a91c70cbb2ec30
+DIST libwebsockets-4.2.2.tar.gz 14589100 BLAKE2B 371bae4790e92aa4f48e51b40fbe2e4efc3b885e07740db14c96146eb857616fd3f7a1b6c83c11fded2791b1db59cb1f6761bc4eebaee918ada7e9bcf4be52d0 SHA512 52d9b4511fc484781108a3036f870905d4427fcbab02f3e84ee38f534ae7d1979c2cc3eec0719f4609226d4aae788a79fe7d99a8506537bbcf8fc3d9b8a7b478
diff --git a/net-libs/libwebsockets/libwebsockets-4.2.2.ebuild b/net-libs/libwebsockets/libwebsockets-4.2.2.ebuild
new file mode 100644
index 000000000000..180d8b2a195a
--- /dev/null
+++ b/net-libs/libwebsockets/libwebsockets-4.2.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A flexible pure-C library for implementing network protocols"
+HOMEPAGE="https://libwebsockets.org/"
+SRC_URI="https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/18" # libwebsockets.so.18
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="access-log caps cgi client dbus generic-sessions http-proxy http2 ipv6
+	+lejp libev libevent libuv mbedtls peer-limits server-status smtp socks5
+	sqlite3 ssl threads zip"
+
+REQUIRED_USE="
+	access-log? ( http2 )
+	generic-sessions? ( smtp sqlite3 )
+	http-proxy? ( client )
+	mbedtls? ( ssl )
+	smtp? ( libuv )
+	socks5? ( client http-proxy )
+	?? ( libev libevent )"
+
+RDEPEND="
+	sys-libs/zlib
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	http-proxy? ( net-libs/libhubbub )
+	libev? ( dev-libs/libev )
+	libevent? ( dev-libs/libevent:= )
+	libuv? ( dev-libs/libuv:= )
+	sqlite3? ( dev-db/sqlite:= )
+	ssl? (
+		!mbedtls? ( dev-libs/openssl:0= )
+		mbedtls? ( net-libs/mbedtls:= )
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Git=ON
+		-DDISABLE_WERROR=ON
+		-DLWS_BUILD_HASH="unknown"
+		-DLWS_HAVE_LIBCAP=$(usex caps)
+		-DLWS_IPV6=$(usex ipv6)
+		-DLWS_ROLE_DBUS=$(usex dbus)
+		-DLWS_SUPPRESS_DEPRECATED_API_WARNINGS=ON
+		-DLWS_WITHOUT_CLIENT=$(usex !client)
+		-DLWS_WITHOUT_TEST_CLIENT=$(usex !client)
+		-DLWS_WITH_ACCESS_LOG=$(usex access-log)
+		-DLWS_WITH_CGI=$(usex cgi)
+		-DLWS_WITH_GENERIC_SESSIONS=$(usex generic-sessions)
+		-DLWS_WITH_HTTP2=$(usex http2)
+		-DLWS_WITH_HTTP_PROXY=$(usex http-proxy)
+		-DLWS_WITH_HUBBUB=$(usex http-proxy)
+		-DLWS_WITH_LEJP=$(usex lejp)
+		-DLWS_WITH_LIBEV=$(usex libev)
+		-DLWS_WITH_LIBEVENT=$(usex libevent)
+		-DLWS_WITH_LIBUV=$(usex libuv)
+		-DLWS_WITH_MBEDTLS=$(usex mbedtls)
+		-DLWS_WITH_PEER_LIMITS=$(usex peer-limits)
+		-DLWS_WITH_SERVER_STATUS=$(usex server-status)
+		-DLWS_WITH_SMTP=$(usex smtp)
+		-DLWS_WITH_SOCKS5=$(usex socks5)
+		-DLWS_WITH_SQLITE3=$(usex sqlite3)
+		-DLWS_WITH_SSL=$(usex ssl)
+		-DLWS_WITH_STATIC=OFF
+		-DLWS_WITH_STRUCT_JSON=$(usex lejp)
+		-DLWS_WITH_THREADPOOL=$(usex threads)
+		-DLWS_WITH_ZIP_FOPS=$(usex zip)
+		-DLWS_WITHOUT_TESTAPPS=ON
+	)
+
+	cmake_src_configure
+}