net-libs/gupnp: bump to 1.0.4

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/net-libs/gupnp/Manifest b/net-libs/gupnp/Manifest
index 99181995fc89..fc4e9cdb461c 100644
--- a/net-libs/gupnp/Manifest
+++ b/net-libs/gupnp/Manifest
@@ -1 +1,2 @@
 DIST gupnp-1.0.3.tar.xz 422912 BLAKE2B 900a2a81982a50239b26ddd5df3f57caac1ee66103e857b9014db7dc694e303c1eaa0633cb467887f3370e97058abc221bd0175c9df11ca4af31e3f802145a66 SHA512 f256757ddf1a31f1dc93dc138401329e40aa063e7452dccaabe53682eebcb1b98cb6429c01d806290587ca9d01d91afce0603627d2d8675ddb68ef919efb6448
+DIST gupnp-1.0.4.tar.xz 427616 BLAKE2B ab5d34e701e253dc48ebafabc908f9aacd7a325805c61b11b5668cfa105d56a37f0d93593eeedd0e63630b986f2a2c18d4d9cdd82b653c9cc7a5d57262a819ef SHA512 54a133ce043e9b3d5ea23041c04fbbf5483aea98a72421cdb59bada0ab2e3ab3fc85452c4c743b794eeb7c929f5ef38bf0e6ba7f9539d86182a77612c898205a
diff --git a/net-libs/gupnp/gupnp-1.0.4.ebuild b/net-libs/gupnp/gupnp-1.0.4.ebuild
new file mode 100644
index 000000000000..6e5cf8b99539
--- /dev/null
+++ b/net-libs/gupnp/gupnp-1.0.4.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+PYTHON_REQ_USE="xml"
+
+inherit gnome2 multilib-minimal python-single-r1 vala
+
+DESCRIPTION="An object-oriented framework for creating UPnP devs and control points"
+HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
+
+LICENSE="LGPL-2"
+SLOT="0/4"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="connman +introspection kernel_linux networkmanager"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	?? ( connman networkmanager )
+"
+
+# prefix: uuid dependency can be adapted to non-linux platforms
+RDEPEND="${PYTHON_DEPS}
+	>=net-libs/gssdp-0.14.15:0=[introspection?,${MULTILIB_USEDEP}]
+	>=net-libs/libsoup-2.48.0:2.4[introspection?,${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
+	>=sys-apps/util-linux-2.24.1-r3[${MULTILIB_USEDEP}]
+	introspection? (
+			>=dev-libs/gobject-introspection-1.36:=
+			$(vala_depend) )
+	connman? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
+	networkmanager? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
+	!net-libs/gupnp-vala
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.14
+	sys-devel/gettext
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+src_prepare() {
+	use introspection && vala_src_prepare
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	local backend=unix
+	use kernel_linux && backend=linux
+	use connman && backend=connman
+	use networkmanager && backend=network-manager
+
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		$(multilib_native_use_enable introspection) \
+		--disable-static \
+		--with-context-manager=${backend}
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/html doc/html || die
+	fi
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	python_fix_shebang "${ED}"/usr/bin/gupnp-binding-tool
+}