summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAmadeusz Żołnowski <aidecoe@gentoo.org>2016-06-01 07:18:42 +0100
committerAmadeusz Żołnowski <aidecoe@gentoo.org>2016-06-01 07:25:28 +0100
commit3247f5002cd9eaebaf830bbbac6ec386a2b27305 (patch)
tree8a333cf228d623d3d2dc2524767adeb4d0722b40 /net-mail
parentapp-emulation/wine: Version bump to 1.9.11. (diff)
downloadgentoo-3247f5002cd9eaebaf830bbbac6ec386a2b27305.tar.gz
gentoo-3247f5002cd9eaebaf830bbbac6ec386a2b27305.tar.bz2
gentoo-3247f5002cd9eaebaf830bbbac6ec386a2b27305.zip
net-mail/notmuch: Apply changes in dependencies only in new rev
Revert changes in notmuch-0.22.ebuild in commit 9cdfbeb940dabdd1d2088752b761e12c605e6efa and reapply changes to newly bumped notmuch-0.22-r1.ebuild only. Changes in dependencies are not so trivial, so better have a backup option for users. Package-Manager: portage-2.3.0_rc1
Diffstat (limited to 'net-mail')
-rw-r--r--net-mail/notmuch/notmuch-0.22-r1.ebuild193
-rw-r--r--net-mail/notmuch/notmuch-0.22.ebuild8
2 files changed, 195 insertions, 6 deletions
diff --git a/net-mail/notmuch/notmuch-0.22-r1.ebuild b/net-mail/notmuch/notmuch-0.22-r1.ebuild
new file mode 100644
index 00000000000..9357a32bed7
--- /dev/null
+++ b/net-mail/notmuch/notmuch-0.22-r1.ebuild
@@ -0,0 +1,193 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit bash-completion-r1 elisp-common eutils flag-o-matic pax-utils \
+ distutils-r1 toolchain-funcs
+
+DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
+HOMEPAGE="http://notmuchmail.org/"
+SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz"
+
+LICENSE="GPL-3"
+# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y. Bump of Y is
+# meant to be binary backward compatible.
+SLOT="0/4"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="
+ nmbug? ( python )
+ python? ( ${PYTHON_REQUIRED_USE} )
+ test? ( crypt debug emacs python )
+ "
+IUSE="crypt debug doc emacs mutt nmbug python test"
+
+CDEPEND="
+ >=app-shells/bash-completion-1.9
+ >=dev-libs/glib-2.22:2
+ >=dev-libs/gmime-2.6.20-r2:2.6
+ >=dev-libs/xapian-1.2.7-r2:=
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ >=sys-libs/zlib-1.2.5.2
+ sys-libs/talloc
+ crypt? ( >=dev-libs/gmime-2.6.20-r2:2.6[smime] )
+ !crypt? ( >=dev-libs/gmime-2.6.20-r2:2.6[-smime] )
+ debug? ( dev-util/valgrind )
+ emacs? ( >=virtual/emacs-23 )
+ python? ( ${PYTHON_DEPS} )
+ "
+DEPEND="${CDEPEND}
+ virtual/pkgconfig
+ doc? ( app-doc/doxygen )
+ test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
+ >=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb
+ crypt? ( dev-libs/openssl ) )
+ "
+RDEPEND="${CDEPEND}
+ crypt? ( app-crypt/gnupg )
+ !crypt? ( !app-crypt/gnupg )
+ nmbug? ( dev-vcs/git )
+ mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
+ dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu
+ virtual/perl-Digest-SHA virtual/perl-File-Path virtual/perl-Getopt-Long
+ virtual/perl-Pod-Parser
+ )
+ "
+
+DOCS=( AUTHORS NEWS README )
+SITEFILE="50${PN}-gentoo.el"
+MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
+MY_PATCHES=( )
+
+bindings() {
+ local ret=0
+
+ if use $1; then
+ pushd bindings/$1 || die
+ shift
+ "$@"
+ ret=$?
+ popd || die
+ fi
+
+ return $ret
+}
+
+pkg_pretend() {
+ if has_version '<net-mail/notmuch-0.18'; then
+ ewarn
+ ewarn "There are few not backward compatible changes between"
+ ewarn "<notmuch-0.18 and >=notmuch-0.18. See NEWS file"
+ ewarn "(0.18 section) for details before first use!"
+ ewarn
+ fi
+}
+
+pkg_setup() {
+ if use emacs; then
+ elisp-need-emacs 23 || die "Emacs version too low"
+ fi
+}
+
+src_prepare() {
+ [[ "${MY_PATCHES[@]}" ]] && epatch "${MY_PATCHES[@]}"
+
+ bindings python distutils-r1_src_prepare
+ bindings python mv README README-python || die
+ mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
+
+ rm -f Makefile.config # assure that new Makefile.config will be generated
+
+ if use debug; then
+ append-cflags -g
+ append-cxxflags -g
+ fi
+}
+
+src_configure() {
+ local myeconfargs=(
+ --bashcompletiondir="$(get_bashcompdir)"
+ --emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
+ --emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
+ --without-ruby
+ --zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+ $(use_with emacs)
+ )
+ tc-export CC CXX
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ V=1 default
+ bindings python distutils-r1_src_compile
+
+ if use mutt; then
+ pushd contrib/notmuch-mutt || die
+ emake notmuch-mutt.1
+ popd || die
+ fi
+
+ if use doc; then
+ pydocs() {
+ pushd docs || die
+ emake html
+ mv html ../python || die
+ popd || die
+ }
+ LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
+ fi
+}
+
+src_test() {
+ pax-mark -m notmuch
+ emake download-test-databases
+ LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" default
+ pax-mark -ze notmuch
+}
+
+src_install() {
+ default
+
+ if use emacs; then
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+ fi
+
+ if use nmbug; then
+ dobin devel/nmbug/nmbug
+ dobin devel/nmbug/notmuch-report
+ fi
+
+ if use mutt; then
+ pushd contrib/notmuch-mutt || die
+ dobin notmuch-mutt
+ doman notmuch-mutt.1
+ insinto /etc/mutt
+ doins notmuch-mutt.rc
+ dodoc README-mutt
+ popd || die
+ fi
+
+ DOCS="" bindings python distutils-r1_src_install
+ use doc && bindings python dohtml -r python
+}
+
+pkg_preinst() {
+ if use mutt && ! [[ -e ${ROOT}/etc/mutt/notmuch-mutt.rc ]]; then
+ elog "To enable notmuch support in mutt, add the following line into"
+ elog "your mutt config file, please:"
+ elog ""
+ elog " source /etc/mutt/notmuch-mutt.rc"
+ fi
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
diff --git a/net-mail/notmuch/notmuch-0.22.ebuild b/net-mail/notmuch/notmuch-0.22.ebuild
index 9357a32bed7..1cf92ced966 100644
--- a/net-mail/notmuch/notmuch-0.22.ebuild
+++ b/net-mail/notmuch/notmuch-0.22.ebuild
@@ -29,13 +29,11 @@ IUSE="crypt debug doc emacs mutt nmbug python test"
CDEPEND="
>=app-shells/bash-completion-1.9
>=dev-libs/glib-2.22:2
- >=dev-libs/gmime-2.6.20-r2:2.6
+ >=dev-libs/gmime-2.6.20:2.6
>=dev-libs/xapian-1.2.7-r2:=
dev-python/sphinx[${PYTHON_USEDEP}]
>=sys-libs/zlib-1.2.5.2
sys-libs/talloc
- crypt? ( >=dev-libs/gmime-2.6.20-r2:2.6[smime] )
- !crypt? ( >=dev-libs/gmime-2.6.20-r2:2.6[-smime] )
debug? ( dev-util/valgrind )
emacs? ( >=virtual/emacs-23 )
python? ( ${PYTHON_DEPS} )
@@ -44,12 +42,10 @@ DEPEND="${CDEPEND}
virtual/pkgconfig
doc? ( app-doc/doxygen )
test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
- >=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb
- crypt? ( dev-libs/openssl ) )
+ >=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb )
"
RDEPEND="${CDEPEND}
crypt? ( app-crypt/gnupg )
- !crypt? ( !app-crypt/gnupg )
nmbug? ( dev-vcs/git )
mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu