proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 65 insertions, 0 deletions

diff --git a/net-misc/connman/connman-1.24.ebuild b/net-misc/connman/connman-1.24.ebuild
new file mode 100644
index 000000000000..9b8f8de93b9e
--- /dev/null
+++ b/net-misc/connman/connman-1.24.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+inherit base systemd
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="http://connman.net"
+SRC_URI="mirror://kernel/linux/network/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="bluetooth debug doc examples +ethernet ofono openvpn openconnect policykit tools vpnc +wifi"
+
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	>=net-firewall/iptables-1.4.8
+	net-libs/gnutls
+	bluetooth? ( net-wireless/bluez )
+	ofono? ( net-misc/ofono )
+	policykit? ( sys-auth/polkit )
+	openvpn? ( net-misc/openvpn )
+	vpnc? ( net-misc/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.39"
+
+PATCHES=( "${FILESDIR}/${PN}-1.16-execinfo-assumptions.patch" )
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--enable-client \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable examples test) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable openconnect openconnect builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable debug) \
+		$(use_enable tools) \
+		--disable-iospm \
+		--disable-hh2serial-gps
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dobin client/connmanctl || die "client installation failed"
+
+	if use doc; then
+		dodoc doc/*.txt
+	fi
+	keepdir /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	systemd_dounit "${FILESDIR}"/connman.service
+}