net-misc/ethflop: New package

ethflop is a DOS TSR that emulates a floppy disk drive.
The emulated (virtual) floppy disk is, in fact, stored on a Linux server as a
floppy image. All the communication between ethflop (the TSR)
and ethflopd (the Linux daemon) is exchanged over raw Ethernet. No need for
any network configuration - the DOS PC only needs to have some kind of
Ethernet adapter and a suitable packet driver. The Linux server and
the DOS PC must be connected do the common Ethernet segment (same LAN).

Closes: https://github.com/gentoo/gentoo/pull/13307
Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/net-misc/ethflop/ethflop-20191003.ebuild b/net-misc/ethflop/ethflop-20191003.ebuild
new file mode 100644
index 000000000000..f0b9e708f26e
--- /dev/null
+++ b/net-misc/ethflop/ethflop-20191003.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd toolchain-funcs
+
+DESCRIPTION="A network-backed floppy emulator for DOS"
+HOMEPAGE="http://ethflop.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.zip"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="tsr"
+
+BDEPEND="
+	app-arch/unzip
+	tsr? ( dev-lang/nasm )
+"
+
+PATCHES=( "${FILESDIR}/${P}-makefile.patch" )
+
+S="${WORKDIR}"
+
+src_compile() {
+	tc-export CC
+	default
+
+	use tsr && emake tsr
+}
+
+src_install() {
+	dobin ethflopd
+
+	if use tsr; then
+		insinto /usr/share/ethflop
+		doins ethflop.com
+	fi
+
+	newinitd "${FILESDIR}"/ethflopd.initd ethflopd
+	newconfd "${FILESDIR}"/ethflopd.confd ethflopd
+	systemd_dounit "${FILESDIR}"/ethflopd.service
+
+	dodoc ethflop.txt
+}