proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 112 insertions, 0 deletions

diff --git a/net-misc/freerdp/freerdp-1.1.0_beta1_p20150312.ebuild b/net-misc/freerdp/freerdp-1.1.0_beta1_p20150312.ebuild
new file mode 100644
index 000000000000..baa511f43651
--- /dev/null
+++ b/net-misc/freerdp/freerdp-1.1.0_beta1_p20150312.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit cmake-utils vcs-snapshot
+
+if [[ ${PV} != 9999* ]]; then
+	COMMIT="770c67d340d5f0a7b48d53a1ae0fc23aff748fc4"
+	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+else
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
+		https://github.com/FreeRDP/FreeRDP.git"
+	KEYWORDS=""
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="alsa +client cups debug directfb doc ffmpeg gstreamer jpeg
+	pulseaudio server smartcard cpu_flags_x86_sse2 test usb X xinerama xv"
+
+RDEPEND="
+	dev-libs/openssl
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	client? (
+		usb? (
+			virtual/libudev:0=
+			sys-apps/util-linux:0=
+			dev-libs/dbus-glib:0=
+			virtual/libusb:1=
+		)
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			xinerama? ( x11-libs/libXinerama )
+			xv? ( x11-libs/libXv )
+		)
+	)
+	directfb? ( dev-libs/DirectFB )
+	ffmpeg? ( virtual/ffmpeg )
+	gstreamer? (
+		media-libs/gstreamer:0.10
+		media-libs/gst-plugins-base:0.10
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}
+	<dev-util/cmake-3.1
+	virtual/pkgconfig
+	client? ( X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) ) )
+"
+
+DOCS=( README )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.1.0_beta1_p20130710-uclibc.patch"
+	"${FILESDIR}/${PN}-1.1.0_beta1_p20130710-cmake.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with alsa ALSA)
+		$(cmake-utils_use_with client CLIENT)
+		$(cmake-utils_use_with cups CUPS)
+		$(cmake-utils_use_with debug DEBUG_ALL)
+		$(cmake-utils_use_with doc MANPAGES)
+		$(cmake-utils_use_with directfb DIRECTFB)
+		$(cmake-utils_use_with ffmpeg FFMPEG)
+		$(cmake-utils_use_with gstreamer GSTREAMER)
+		$(cmake-utils_use_with jpeg JPEG)
+		$(cmake-utils_use_with pulseaudio PULSE)
+		$(cmake-utils_use_with server SERVER)
+		$(cmake-utils_use_with smartcard PCSC)
+		$(cmake-utils_use_with cpu_flags_x86_sse2 SSE2)
+		$(cmake-utils_use usb CHANNEL_URBDRC)
+		$(cmake-utils_use_with X X11)
+		$(cmake-utils_use_with xinerama XINERAMA)
+		$(cmake-utils_use_with xv XV)
+		$(cmake-utils_use_build test TESTING)
+	)
+	cmake-utils_src_configure
+}