proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 73 insertions, 0 deletions

diff --git a/net-misc/gsasl/gsasl-1.8.0-r1.ebuild b/net-misc/gsasl/gsasl-1.8.0-r1.ebuild
new file mode 100644
index 000000000000..e967217c06c0
--- /dev/null
+++ b/net-misc/gsasl/gsasl-1.8.0-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+inherit autotools eutils
+
+DESCRIPTION="The GNU SASL client, server, and library"
+HOMEPAGE="http://www.gnu.org/software/gsasl/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc gcrypt idn kerberos nls ntlm static-libs +threads"
+
+DEPEND="
+	gcrypt? ( dev-libs/libgcrypt:0 )
+	idn? ( net-dns/libidn )
+	kerberos? ( virtual/krb5 )
+	nls? ( >=sys-devel/gettext-0.18.1 )
+	ntlm? ( net-libs/libntlm )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-gss-extra.patch"
+	sed -i -e '/gl_WARN_ADD(\[-Werror/d' \
+           -e 's/ -Werror//' configure.ac || die
+	sed -i -e 's/ -Werror//' lib/configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local krb5_impl
+	if use kerberos; then
+		krb5_impl="--with-gssapi-impl="
+		krb5_impl+=$(has_version app-crypt/mit-krb5 && echo "mit" || echo "heimdal")
+	fi
+	econf \
+		--enable-client \
+		--enable-server \
+		--disable-valgrind-tests \
+		--disable-rpath \
+		--without-libshishi \
+		--without-libgss \
+		--disable-kerberos_v5 \
+		$(use_enable kerberos gssapi) \
+		${krb5_impl} \
+		$(use_enable kerberos gs2) \
+		$(use_with gcrypt libgcrypt) \
+		$(use_enable nls) \
+		$(use_with idn stringprep) \
+		$(use_enable ntlm) \
+		$(use_with ntlm libntlm) \
+		$(use_enable static-libs static) \
+		$(use_enable threads)
+}
+
+src_install() {
+	default
+	if ! use static-libs; then
+		rm -f "${D}"/usr/lib*/lib*.la
+	fi
+	doman doc/gsasl.1 doc/man/*.3
+
+	if use doc; then
+		dodoc doc/*.{eps,ps,pdf}
+		dohtml doc/*.html
+		docinto examples
+		dodoc examples/*.c
+	fi
+}