proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 65 insertions, 0 deletions

diff --git a/net-misc/i2pd/i2pd-0.6.0.ebuild b/net-misc/i2pd/i2pd-0.6.0.ebuild
new file mode 100644
index 000000000000..6dc85b5be117
--- /dev/null
+++ b/net-misc/i2pd/i2pd-0.6.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils systemd user cmake-utils
+
+DESCRIPTION="A C++ daemon for accessing the I2P anonymous network"
+HOMEPAGE="https://github.com/PrivacySolutions/i2pd"
+SRC_URI="https://github.com/PrivacySolutions/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_aes i2p-hardening static"
+
+RDEPEND="!static? ( >=dev-libs/boost-1.46[threads] )
+	!static? ( dev-libs/crypto++ )"
+DEPEND="${RDEPEND}
+	static? ( >=dev-libs/boost-1.46[static-libs,threads] )
+	static? ( dev-libs/crypto++[static-libs] )
+	>=dev-util/cmake-2.8.5
+	i2p-hardening? ( >=sys-devel/gcc-4.6 )
+	|| ( >=sys-devel/gcc-4.6 >=sys-devel/clang-3.3 )"
+
+I2PD_USER="${I2PD_USER:-i2pd}"
+I2PD_GROUP="${I2PD_GROUP:-i2pd}"
+
+CMAKE_USE_DIR="${S}/build"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with cpu_flags_x86_aes AESNI)
+		$(cmake-utils_use_with i2p-hardening HARDENING)
+		$(cmake-utils_use_with static STATIC)
+		-DWITH_LIBRARY=OFF
+		-DWITH_BINARY=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc README.md
+	doman "${FILESDIR}/${PN}.1"
+	keepdir /var/lib/i2pd/
+	fowners "${I2PD_USER}:${I2PD_GROUP}" /var/lib/i2pd/
+	fperms 700 /var/lib/i2pd/
+	insinto /etc/
+	doins "${FILESDIR}/${PN}.conf"
+	fowners "${I2PD_USER}:${I2PD_GROUP}" "/etc/${PN}.conf"
+	fperms 600 "/etc/${PN}.conf"
+	dodir /usr/share/i2pd
+	cp -R "${S}/contrib/certificates" "${D}/var/lib/i2pd" || die "Install failed!"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	doenvd "${FILESDIR}/99${PN}"
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotate" "${PN}"
+}
+
+pkg_setup() {
+	enewgroup "${I2PD_GROUP}"
+	enewuser "${I2PD_USER}" -1 -1 "/var/lib/run/${PN}" "${I2PD_GROUP}"
+}