proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 52 insertions, 0 deletions

diff --git a/net-misc/networkmanager-vpnc/networkmanager-vpnc-1.0.0.ebuild b/net-misc/networkmanager-vpnc/networkmanager-vpnc-1.0.0.ebuild
new file mode 100644
index 000000000000..5765c3207c94
--- /dev/null
+++ b/net-misc/networkmanager-vpnc/networkmanager-vpnc-1.0.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+GCONF_DEBUG="no"
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome2
+
+DESCRIPTION="NetworkManager VPNC plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 ~arm x86"
+IUSE="gtk test"
+
+RDEPEND="
+	>=net-misc/networkmanager-0.9.10:=
+	>=dev-libs/dbus-glib-0.74
+	>=dev-libs/glib-2.32:2
+	>=net-misc/vpnc-0.5
+	gtk? (
+		app-crypt/libsecret
+		>=gnome-extra/nm-applet-0.9.9.0
+		>=x11-libs/gtk+-3.4:3
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Test will fail if the machine doesn't have a particular locale installed
+	# upstream bug #742708
+	sed '/test_non_utf8_import (plugin/ d' \
+		-i properties/tests/test-import-export.c || die "sed failed"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		$(use_with gtk gnome) \
+		$(use_with test tests)
+}