net-misc/nextcloud-client: 2.6.3 bump

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

2 files changed, 90 insertions, 0 deletions

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index 3cc1b4e6d215..fb2f88cac7d1 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -2,3 +2,4 @@ DIST nextcloud-client-2.5.2.tar.gz 18995992 BLAKE2B 6ad23962d327c1feeec34f590920
 DIST nextcloud-client-2.6.0.tar.gz 18789917 BLAKE2B db5c703ecf630a96c141c9c8a7b15894c5a679e1b36217f38a02cd55307fadb5ea19c13ab44371fbbcf0610ddafdd2fb0c1ef6119db04808b94a72dbfb27da9a SHA512 161733540de85c436e204b150fb91b527737fee213e569335248ce7c6e1446497aad5e3fa814b3f98a1ec0cdb94fad64ccc0807eb953a94170f9d40abb478545
 DIST nextcloud-client-2.6.1.tar.gz 18947504 BLAKE2B 940145f9f633ad35e740a92d44d0d7172f7c0883bf29951694dd540213dcfc64f9d480a1cd38b586842dad8c96d3c2948d6e8af6042005f0cd23d9b6d3eab7c6 SHA512 dbda59f5ef6f5f85d8344732be4a0b51e51fa9d0180d5b589f79ab6fe1bacf3a63879aee2f297bc76d6257dd830b38c695cf88f98b9e3f788acf9d6b2f11f619
 DIST nextcloud-client-2.6.2.tar.gz 18982053 BLAKE2B 53f4d13b42f50a272012909ed5c937b0a37543f11b8ef0119db670107ed10629d79cb2fcfbbe9148ff847f7ef9e38183f613ae3162206bf9e8f7424ae8280b72 SHA512 b56a7d6751381ffb546b0c8a4b9dbb7991f523ac2ff06dbc87ee36927a4326f57f520ea96a2116ead5d36db6b9900f552834ec9dff8ad5adf80e896829428199
+DIST nextcloud-client-2.6.3.tar.gz 18983292 BLAKE2B 89fdb35c12f4d126c19f31d09d54e027f9edf684fa4904bfba0e7c49a628295aabe00f2b6bc79496876a252dbc9d82772a95bcc59ae4220f8c91dd09bd2661d9 SHA512 ddeb8a32e0208bc415bf421cb3ce05713adb617fa78c0b5cb4d894c9e8d3499dcc495c115de3ea7abb0c402eef4bc64ede8c59a7f056acda47779096fedc8025
diff --git a/net-misc/nextcloud-client/nextcloud-client-2.6.3.ebuild b/net-misc/nextcloud-client/nextcloud-client-2.6.3.ebuild
new file mode 100644
index 000000000000..0efd5f09b271
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-2.6.3.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus shibboleth test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	shibboleth? ( dev-qt/qtwebkit:5 )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.6.1-include_tests.patch )
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=$(usex !shibboleth)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}