net-misc/s6-networking: Bump to 2.3.0.1, fix #618156

1 files changed, 70 insertions, 0 deletions

diff --git a/net-misc/s6-networking/s6-networking-2.3.0.1.ebuild b/net-misc/s6-networking/s6-networking-2.3.0.1.ebuild
new file mode 100644
index 000000000000..ce24c644ece7
--- /dev/null
+++ b/net-misc/s6-networking/s6-networking-2.3.0.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit versionator
+
+DESCRIPTION="suite of small networking utilities for Unix systems"
+HOMEPAGE="https://www.skarnet.org/software/s6-networking/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(get_version_component_range 1-2)"
+KEYWORDS="~amd64 ~x86"
+IUSE="ssl static static-libs"
+
+DEPEND=">=sys-devel/make-3.81
+	static? (
+		>=dev-lang/execline-2.3.0.1[static-libs]
+		>=dev-libs/skalibs-2.5.1.0[static-libs]
+		>=net-dns/s6-dns-2.2.0.0[static-libs]
+		>=sys-apps/s6-2.5.1.0[static-libs]
+		ssl? ( >=dev-libs/libressl-2.4.5[static-libs] )
+	)
+	!static? (
+		>=dev-lang/execline-2.3.0.1[static=]
+		>=dev-libs/skalibs-2.5.1.0
+		>=net-dns/s6-dns-2.2.0.0[static=]
+		>=sys-apps/s6-2.5.1.0[static=]
+		ssl? ( >=dev-libs/libressl-2.4.5 )
+	)
+"
+RDEPEND="
+	>=dev-lang/execline-2.3.0.1:=[!static?]
+	>=sys-apps/s6-2.5.1.0:=[!static?]
+	!static? (
+		>=dev-libs/skalibs-2.5.1.0:=
+		>=net-dns/s6-dns-2.2.0.0:=
+		ssl? ( >=dev-libs/libressl-2.4.5:= )
+	)
+"
+
+HTML_DOCS="doc/*"
+
+src_prepare() {
+	default
+
+	# Remove QA warning about LDFLAGS addition
+	sed -i "s/tryldflag LDFLAGS_AUTO -Wl,--hash-style=both/:/" "${S}/configure" || die
+
+	# configure overrides gentoo's -fstack-protector default
+	sed -i "/^tryflag CFLAGS_AUTO -fno-stack-protector$/d" "${S}/configure" || die
+}
+
+src_configure() {
+	econf \
+		--bindir=/bin \
+		--dynlibdir=/$(get_libdir) \
+		--libdir=/usr/$(get_libdir)/${PN} \
+		--with-dynlib=/$(get_libdir) \
+		--with-lib=/usr/$(get_libdir)/s6 \
+		--with-lib=/usr/$(get_libdir)/s6-dns \
+		--with-lib=/usr/$(get_libdir)/skalibs \
+		--with-sysdeps=/usr/$(get_libdir)/skalibs \
+		$(use_enable ssl ssl libressl) \
+		$(use_enable !static shared) \
+		$(use_enable static allstatic) \
+		$(use_enable static static-libc) \
+		$(use_enable static-libs static)
+}