net-misc/remmina: add 1.4.29

Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index af2a629a377f..dbe865b9bf24 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,2 +1,3 @@
 DIST Remmina-v1.4.27.tar.gz 3479987 BLAKE2B 96d4df06558a267db8605dc03de729061e303f9cebec84369ec3bdeeb19d4a377accaf224603ff9ba79bb9f1cecfa66519e6e02e328f42d24c46bdf3e1fabfa6 SHA512 2fff81a1a721b8ca87698697952bb1080cde6affc86c324f6fc30cc329ead57f0e617c39efeeee30890ad4812e719cee22a0b84df43aa1bc7db571607f208bfd
 DIST Remmina-v1.4.28.tar.gz 3553916 BLAKE2B d27598c57e1d68c6c8e4da0a4d2f2cf056cbb2f532297ef01881e87a1c11861ac2dc0e0ee490da4ace18140dcb1d04650bb54635a959bfe828de363b64f98558 SHA512 58f84044a5285edfe739b0f6f60cffe05c79e57453d39173d6c17ba9e5e63e9938a19ce69564cf2a6c254d9f2b6bb426d7518def5c961b3c296f2897509fc931
+DIST Remmina-v1.4.29.tar.gz 3557543 BLAKE2B 9660b4c0a608509fa06f7f61ba352b4bebf78e7123b5a2d1a21c242782ac03bd07a8cd677735fccc633749f92c57bbd72460a12dabd08f520ddd977184758201 SHA512 477da48a88efe06f4fa68a6054b4dba83d5e628a1ccffc6f14a712b49b8ce8af44ab0eef4c1e8e078e55d1554132f3539f331a99c30b8302f5b71fc96cb965c6
diff --git a/net-misc/remmina/remmina-1.4.29.ebuild b/net-misc/remmina/remmina-1.4.29.ebuild
new file mode 100644
index 000000000000..988d70ef89aa
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.29.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake optfeature python-single-r1 xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+appindicator crypt cups examples gnome-keyring gvnc kwallet nls python spice ssh rdp telemetry vnc wayland webkit zeroconf"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3[wayland?]
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	gnome-keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet )
+	python? ( ${PYTHON_DEPS} )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	spice? ( app-emulation/spice-protocol )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_LIBAPPINDICATOR=$(usex appindicator ON OFF)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_PYTHONLIBS=$(usex python ON OFF)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_X2GO=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+}