net-misc/taylor-uucp: modernise ebuild

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 23 insertions, 16 deletions

diff --git a/net-misc/taylor-uucp/taylor-uucp-1.07-r4.ebuild b/net-misc/taylor-uucp/taylor-uucp-1.07-r4.ebuild
index 1f216fb1763e..40489f01df10 100644
--- a/net-misc/taylor-uucp/taylor-uucp-1.07-r4.ebuild
+++ b/net-misc/taylor-uucp/taylor-uucp-1.07-r4.ebuild
@@ -1,24 +1,28 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="5"
+EAPI=7
 
-inherit eutils flag-o-matic autotools
+inherit autotools flag-o-matic
 
 DESCRIPTION="Taylor UUCP"
 HOMEPAGE="https://www.airs.com/ian/uucp.html"
 SRC_URI="mirror://gnu/uucp/uucp-${PV}.tar.gz"
+S="${WORKDIR}/uucp-${PV}"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~alpha amd64 ~arm ~ia64 ppc sparc x86"
 
-S="${WORKDIR}/uucp-${PV}"
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+	"${FILESDIR}"/${P}-fprintf.patch
+	"${FILESDIR}"/${P}-remove-extern.patch
+)
 
 src_prepare() {
-	epatch "${FILESDIR}"/${P}-gentoo.patch
-	epatch "${FILESDIR}"/${P}-fprintf.patch
-	epatch "${FILESDIR}"/${P}-remove-extern.patch
+	default
+
 	mv configure.{in,ac} || die
 	sed -i 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die
 	eautoreconf
@@ -32,7 +36,6 @@ src_configure() {
 src_install() {
 	dodir /usr/share/man/man{1,8}
 	dodir /usr/share/info
-	dodir /etc/uucp
 	dodir /usr/bin /usr/sbin
 	diropts -o uucp -g uucp -m 0750
 	keepdir /var/log/uucp /var/spool/uucp
@@ -40,19 +43,23 @@ src_install() {
 	keepdir /var/spool/uucppublic
 
 	emake \
-		"prefix=${D}/usr" \
-		"sbindir=${D}/usr/sbin" \
-		"bindir=${D}/usr/bin" \
-		"man1dir=${D}/usr/share/man/man1" \
-		"man8dir=${D}/usr/share/man/man8" \
-		"newconfigdir=${D}/etc/uucp" \
-		"infodir=${D}/usr/share/info" \
+		"prefix=${ED}/usr" \
+		"sbindir=${ED}/usr/sbin" \
+		"bindir=${ED}/usr/bin" \
+		"man1dir=${ED}/usr/share/man/man1" \
+		"man8dir=${ED}/usr/share/man/man8" \
+		"newconfigdir=${ED}/etc/uucp" \
+		"infodir=${ED}/usr/share/info" \
 		install install-info
+
 	sed -i -e 's:/usr/spool:/var/spool:g' sample/config
-	cp sample/* "${ED}/etc/uucp" || die
+
+	insinto etc/uucp
+	doins sample/*
+
 	dodoc ChangeLog NEWS README TODO
 }
 
 pkg_preinst() {
-	usermod -s /bin/bash uucp
+	usermod -s /bin/bash uucp || die
 }