net-news/quiterss: 0.19.3 version bump

Closes: https://bugs.gentoo.org/700484
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/net-news/quiterss/quiterss-0.19.3.ebuild b/net-news/quiterss/quiterss-0.19.3.ebuild
new file mode 100644
index 000000000000..2f3aae882830
--- /dev/null
+++ b/net-news/quiterss/quiterss-0.19.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils xdg
+
+DESCRIPTION="A Qt-based RSS/Atom feed reader"
+HOMEPAGE="https://quiterss.org"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/QuiteRSS/quiterss.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/QuiteRSS/quiterss/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE=""
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-db/sqlite-3.11.1:3
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsingleapplication[X,qt5(+)]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwebkit:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	sed -e "s/exists(.git)/0/" -i QuiteRSS.pro || die
+}
+
+src_configure() {
+	local myqmakeargs=(
+		PREFIX="${EPREFIX}/usr"
+		SYSTEMQTSA=1
+	)
+	eqmake5 "${myqmakeargs[@]}"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}