net-news/rssguard: Call xdg_icon_cache_update

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/net-news/rssguard/rssguard-3.5.9-r1.ebuild b/net-news/rssguard/rssguard-3.5.9-r1.ebuild
new file mode 100644
index 000000000000..d7491fc3d340
--- /dev/null
+++ b/net-news/rssguard/rssguard-3.5.9-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic xdg-utils qmake-utils
+
+DESCRIPTION="Tiny RSS and Atom feed reader"
+HOMEPAGE="https://github.com/martinrotter/rssguard"
+SRC_URI="https://github.com/martinrotter/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug webengine"
+
+BDEPEND="dev-qt/linguist-tools:5"
+DEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	webengine? ( dev-qt/qtwebengine:5[widgets] )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${P}-qt-5.14.patch" )
+
+src_configure() {
+	# CONFIG+=ltcg is needed because of https://github.com/martinrotter/rssguard/issues/156
+	eqmake5 \
+		CONFIG+=$(usex debug debug release) \
+		$(is-flagq -flto* && echo "CONFIG+=ltcg") \
+		USE_WEBENGINE=$(usex webengine) \
+		PREFIX="${EPREFIX}"/usr \
+		INSTALL_ROOT=.
+}
+
+src_install() {
+	emake install INSTALL_ROOT="${D}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}