net-wireless/gnome-bluetooth: add 42.8

Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/net-wireless/gnome-bluetooth/Manifest b/net-wireless/gnome-bluetooth/Manifest
index 8ed0c18baef9..cdbff1e77fa6 100644
--- a/net-wireless/gnome-bluetooth/Manifest
+++ b/net-wireless/gnome-bluetooth/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-bluetooth-42.6.tar.xz 304668 BLAKE2B d3dbc6c41de456e357e16b8d714f96bbcf9fc28776d361d4fc7d6d2c6ed7bb21496cc5f5eb02a24ce0b48c40ca2fefd80a36dda78e3ae63f67051b6f6a358258 SHA512 4c939a2f19c656ecc03535a203e3eed582a288abb3862ae92c517e611395e940ac65412281c9cd238cb8da99a2019505dd5bb2a687f143dd02b24b11d40b5450
 DIST gnome-bluetooth-42.7.tar.xz 304736 BLAKE2B 6b3eed3d93184c01a98307458ac1570ce97b46fea116d24ec54aa499aa45ce3245cb7982d8fda01d731ff0455b450c6513a86d52a6f7d7ee724726e476ddfd78 SHA512 dcbc5f54c2eb9eea29fea91e3c2c60ab3b6bf23effbe79df54dfc91834dda10fef144fb3abf6dc8a4651b5cc18bc666d4ab0574be793d31d199d1514e96c2a59
+DIST gnome-bluetooth-42.8.tar.xz 304908 BLAKE2B c487e0c278b316ecdcbdd39421389ce95024b06bf0e350d59dcac06d7a7e8b982da12b1088701e479d0b5c64b123899a5351a00c477208946bb1f44f3c8f30a6 SHA512 1c3d1db874b54ebae3cf59e526db8ff71131daea0c994abeefd95b51abf590bbba0baa8314ebbd1d3efe7973021327c7b8257163ed8f0567fe610b4e0c3dba88
diff --git a/net-wireless/gnome-bluetooth/gnome-bluetooth-42.8.ebuild b/net-wireless/gnome-bluetooth/gnome-bluetooth-42.8.ebuild
new file mode 100644
index 000000000000..c09f8f7bf93a
--- /dev/null
+++ b/net-wireless/gnome-bluetooth/gnome-bluetooth-42.8.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeBluetooth"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="3/13" # subslot = libgnome-bluetooth-3 soname version
+IUSE="gtk-doc +introspection sendto test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.44:2
+	>=gui-libs/gtk-4.4:4[introspection?]
+	media-libs/gsound
+	>=gui-libs/libadwaita-1.1:1
+	>=x11-libs/libnotify-0.7.0
+	virtual/libudev:=
+	>=sys-power/upower-0.99.14:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	acct-group/plugdev
+	virtual/udev
+	>=net-wireless/bluez-5
+	sendto? ( !net-wireless/gnome-bluetooth:2 )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.9 )
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			>=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version ">=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/dbus-python[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	# Check for python is unconditional
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use sendto)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Workaround test failures caused by flatpak being installed that adds to XDG_DATA_DIRS
+	gnome_environment_reset
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share
+
+	meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}