sci-chemistry/gnome-chemistry-utils: Many fixes from Debian

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/sci-chemistry/gnome-chemistry-utils/Manifest b/sci-chemistry/gnome-chemistry-utils/Manifest
index 261784305584..16dad10fb3d4 100644
--- a/sci-chemistry/gnome-chemistry-utils/Manifest
+++ b/sci-chemistry/gnome-chemistry-utils/Manifest
@@ -1 +1,2 @@
 DIST gnome-chemistry-utils-0.14.17.tar.xz 5911248 BLAKE2B 5d3bb4afbe3d3f620912e810717f08674d56a11c384b1fb239788cfbbb625797e8c52de2b6d940ae7f3d83847533afedd6ed961b1fa0ea1cec62dda88de1a6df SHA512 01bb964e1484e028c5965f1de74798422b448823047fcadf668dc76e98b3e214939a2f031d0182c717c4376f490e5969a4604ee66d1763e6b480032d7ae97468
+DIST gnome-chemistry-utils_0.14.17-5.debian.tar.xz 67836 BLAKE2B af9365a25740d11f798daaf38880e040c6d66b5ba0b27f52da9bc4f1391568f572eeefa6360089382a966c630b9e362276a535553faa0c0d1a498619fb500543 SHA512 15bb81b1a03c778807dd16d98bc8608fb4d0488ea33d277a048487b3b440abd0ba64edb907a57650e9b0be9dc1a6826a9baaf4a74fc140836f38baf790a767ec
diff --git a/sci-chemistry/gnome-chemistry-utils/gnome-chemistry-utils-0.14.17_p5.ebuild b/sci-chemistry/gnome-chemistry-utils/gnome-chemistry-utils-0.14.17_p5.ebuild
new file mode 100644
index 000000000000..f9bcba2440cb
--- /dev/null
+++ b/sci-chemistry/gnome-chemistry-utils/gnome-chemistry-utils-0.14.17_p5.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools xdg
+
+DESCRIPTION="Programs and library containing GTK widgets and C++ classes related to chemistry"
+HOMEPAGE="http://gchemutils.nongnu.org/"
+SRC_URI="
+	http://download.savannah.gnu.org/releases/gchemutils/$(ver_cut 1-2)/${P/_p*}.tar.xz
+	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV/_p*}-${PV/*_p}.debian.tar.xz
+"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-3"
+IUSE="gnumeric"
+
+RDEPEND="
+	>=dev-libs/glib-2.36.0:2
+	>=dev-libs/libxml2-2.4.16:2
+	>=gnome-extra/libgsf-1.14.9
+	>=sci-chemistry/bodr-5
+	>=sci-chemistry/chemical-mime-data-0.1.94
+	>=sci-chemistry/openbabel-2.3.0:0
+	>=x11-libs/cairo-1.6.0
+	>=x11-libs/gdk-pixbuf-2.22.0
+	>=x11-libs/goffice-0.10.12
+	x11-libs/gtk+:3
+	>=x11-libs/libX11-1.0.0
+	gnumeric? ( >=app-office/gnumeric-1.12.42:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-doc/doxygen
+	app-text/yelp-tools
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${P/_p*}"
+
+src_prepare() {
+	xdg_src_prepare
+
+	# We don't have openbabel3 yet
+	sed -i -e '/openbabel-v3/d' "${WORKDIR}"/debian/patches/series || die
+        # Debian patches
+        for p in $(<"${WORKDIR}"/debian/patches/series) ; do
+        	eapply -p1 "${WORKDIR}/debian/patches/${p}"
+	done
+
+	eautoreconf
+}
+
+src_configure() {
+	# lasem is not in the tree
+	econf \
+		--without-lasem \
+		--disable-mozilla-plugin \
+		--disable-update-databases
+}
+
+src_install() {
+	default
+
+	mv "${ED}"/usr/share/appdata "${ED}"/usr/share/metainfo || die
+	rm -rf "${ED}"/usr/share/mimelnk/ || die
+
+	find "${D}" -name '*.la' -type f -delete || die
+}