sci-geosciences/geocode-glib: bump to 3.26.0

Remove long unnecessary (I think) gvfs[http] dep; old version
did use g_file_new_for_uri on a http:// URI, but it's all
direct libsoup nowadays, with g_file for local cache file only.

Re-enable tests and remove unnecessary dbus machinery, as
current tests seem to make no use of it. Patch the test suite
to not install tests.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/sci-geosciences/geocode-glib/geocode-glib-3.26.0.ebuild b/sci-geosciences/geocode-glib/geocode-glib-3.26.0.ebuild
new file mode 100644
index 000000000000..018bb7e4086a
--- /dev/null
+++ b/sci-geosciences/geocode-glib/geocode-glib-3.26.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome.org meson xdg
+
+DESCRIPTION="GLib helper library for geocoding services"
+HOMEPAGE="https://git.gnome.org/browse/geocode-glib"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gtk-doc +introspection test"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=dev-libs/json-glib-0.99.2[introspection?]
+	>=net-libs/libsoup-2.42:2.4[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.13
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/disable-installed-tests.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test enable-installed-tests) # Actual installation to live system is sedded out, but we need this for running them in src_test
+		$(meson_use introspection enable-introspection)
+		$(meson_use gtk-doc enable-gtk-doc)
+	)
+	meson_src_configure
+}