sci-libs/cln: version bump

also add arm64 keyword

Gentoo-Bug: 586990

Package-Manager: portage-2.3.0_rc1
Signed-off-by: Yixun Lan <dlan@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/sci-libs/cln/cln-1.3.4.ebuild b/sci-libs/cln/cln-1.3.4.ebuild
new file mode 100644
index 000000000000..801baf9345cb
--- /dev/null
+++ b/sci-libs/cln/cln-1.3.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools-utils flag-o-matic
+
+DESCRIPTION="Class library (C++) for numbers"
+HOMEPAGE="http://www.ginac.de/CLN/"
+SRC_URI="http://www.ginac.de/CLN/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc examples static-libs"
+
+RDEPEND="dev-libs/gmp:0="
+DEPEND="${RDEPEND}
+	doc? ( virtual/latex-base )"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.3.2-arm.patch )
+
+pkg_setup() {
+	use sparc && append-cppflags -DNO_ASM
+	use hppa && append-cppflags -DNO_ASM
+	use arm && append-cppflags -DNO_ASM
+}
+
+src_prepare() {
+	# avoid building examples
+	# do it in Makefile.in to avoid time consuming eautoreconf
+	sed -i \
+		-e '/^SUBDIRS.*=/s/examples doc benchmarks/doc/' \
+		Makefile.in || die
+	autotools-utils_src_prepare
+}
+
+src_compile() {
+	autotools-utils_src_compile
+	if use doc; then
+		cd "${BUILD_DIR}"
+		export VARTEXFONTS="${T}/fonts"
+		emake html pdf
+		DOCS=("${BUILD_DIR}/doc/cln.pdf")
+		HTML_DOCS=("${BUILD_DIR}/doc/")
+	fi
+}
+
+src_install () {
+	autotools-utils_src_install
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.cc
+	fi
+}