sci-libs/coinor-bonmin: bump to 1.8.8, ported to EAPI 7

Cleaned up old workarounds, reworked deps, and no longer generate
the pdf given it's included in the tarball.

USE=examples removed, now installed unconditionally (small files).
USE=doc now installs html docs.
USE=glpk removed, was a noop.
USE=static-libs removed.

Package-Manager: Portage-3.0.15, Repoman-3.0.2
Signed-off-by: Ionen Wolkens <sudinave@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/sci-libs/coinor-bonmin/coinor-bonmin-1.8.8.ebuild b/sci-libs/coinor-bonmin/coinor-bonmin-1.8.8.ebuild
new file mode 100644
index 000000000000..7ec47de50280
--- /dev/null
+++ b/sci-libs/coinor-bonmin/coinor-bonmin-1.8.8.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="COIN-OR Basic Open-source Nonlinear Mixed INteger programming"
+HOMEPAGE="https://projects.coin-or.org/Bonmin/"
+SRC_URI="https://github.com/coin-or/Bonmin/archive/releases/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/Bonmin-releases-${PV}/Bonmin"
+
+LICENSE="EPL-1.0"
+SLOT="0/4"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	sci-libs/coinor-cbc:=
+	sci-libs/coinor-cgl:=
+	sci-libs/coinor-clp:=
+	sci-libs/coinor-osi:=
+	sci-libs/coinor-utils:=
+	sci-libs/ipopt:=
+	virtual/blas"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen[dot]
+		virtual/latex-base
+	)
+	test? ( sci-libs/coinor-sample )"
+
+src_configure() {
+	econf $(use_with doc dot)
+}
+
+src_compile() {
+	emake all $(usex doc doxydoc '')
+}
+
+src_test() {
+	# Needed given "make check" is a noop and it skips the working one.
+	emake test
+}
+
+src_install() {
+	default
+	dodoc -r examples doc/BONMIN_UsersManual.pdf
+	use doc && dodoc -r doxydoc/html
+
+	# Duplicate or irrelevant files.
+	rm -r "${ED}"/usr/share/coin/doc || die
+	find "${ED}" -name '*.la' -delete || die
+}