sci-libs/libdap: Version bump to 3.18.1

Gentoo-bug: 594374
* Make code C++11 compliant
  (change of noexcept default in C++11)
* Import patches from Debian, make testsuite pass
* Add proper USE="static-libs" handling with econf
  back into src_configure() phase
* Remove installation of testsuite headers and
  convenience library
* Delete .la files unconditionally
* Add missing DEPENDs

Package-Manager: portage-2.3.1

1 files changed, 52 insertions, 0 deletions

diff --git a/sci-libs/libdap/libdap-3.18.1.ebuild b/sci-libs/libdap/libdap-3.18.1.ebuild
new file mode 100644
index 000000000000..8bd51887228f
--- /dev/null
+++ b/sci-libs/libdap/libdap-3.18.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="Implementation of a C++ SDK for DAP 2.0 and 3.2"
+HOMEPAGE="http://opendap.org/"
+SRC_URI="http://www.opendap.org/pub/source/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-2.1 URI )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs test"
+
+RDEPEND="
+	dev-libs/libxml2:2
+	net-misc/curl
+	sys-libs/zlib"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/flex
+	test? ( dev-util/cppunit )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.18.1-fix-buildsystem.patch"
+	"${FILESDIR}/${PN}-3.18.1-fix-c++14.patch"
+	"${FILESDIR}/${PN}-3.18.1-disable-cache-test.patch"
+	"${FILESDIR}/${PN}-3.18.1-disable-dmr-tests.patch"
+	"${FILESDIR}/${PN}-3.18.1-disable-net-tests.patch"
+	"${FILESDIR}/${PN}-3.18.1-disable-broken-tests.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	# package provides .pc files
+	find "${D}" -name '*.la' -delete || die
+}