sci-libs/libgeodecomp: add version 0.4.0.

Add support for libgeodecomp version 0.4.0.

Signed-off-by: Kurt Kanzenbach <kurt@kmk-computers.de>
Closes: https://github.com/gentoo/gentoo/pull/11180
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

1 files changed, 67 insertions, 0 deletions

diff --git a/sci-libs/libgeodecomp/libgeodecomp-0.4.0.ebuild b/sci-libs/libgeodecomp/libgeodecomp-0.4.0.ebuild
new file mode 100644
index 000000000000..98fd350e079c
--- /dev/null
+++ b/sci-libs/libgeodecomp/libgeodecomp-0.4.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils cuda
+
+DESCRIPTION="An auto-parallelizing library to speed up computer simulations"
+HOMEPAGE="http://www.libgeodecomp.org"
+SRC_URI="http://www.libgeodecomp.org/archive/${P}.tar.bz2"
+
+SLOT="0"
+LICENSE="Boost-1.0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc mpi cuda opencl opencv silo hpx visit"
+
+RDEPEND=">=dev-libs/boost-1.48"
+DEPEND="${RDEPEND}
+	doc? (
+		app-doc/doxygen
+		app-text/texlive
+		media-gfx/graphviz
+		)
+	mpi? ( virtual/mpi )
+	cuda? ( dev-util/nvidia-cuda-toolkit )
+	opencl? ( virtual/opencl )
+	opencv? ( media-libs/opencv )
+	silo? ( sci-libs/silo )
+	hpx? ( sys-cluster/hpx )
+	visit? ( sci-visualization/visit )"
+
+S="${WORKDIR}/${P}"
+PATCHES=( "${FILESDIR}/${P}-scotch.patch" "${FILESDIR}/${P}-libdir.patch" )
+
+src_prepare() {
+	cmake-utils_src_prepare
+	use cuda && cuda_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MPI=$(usex mpi)
+		-DWITH_CUDA=$(usex cuda)
+		-DWITH_OPENCL=$(usex opencl)
+		-DWITH_OPENCV=$(usex opencv)
+		-DWITH_SILO=$(usex silo)
+		-DWITH_SCOTCH=false
+		-DWITH_HPX=$(usex hpx)
+		-DWITH_VISIT=$(usex visit)
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	use doc && cmake-utils_src_make doc
+}
+
+src_install() {
+	DOCS=( README )
+	use doc && HTML_DOCS=( doc/html/* )
+	cmake-utils_src_install
+}
+
+src_test() {
+	cmake-utils_src_make check
+}