proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 55 insertions, 0 deletions

diff --git a/sci-libs/mmtk/mmtk-2.7.9.ebuild b/sci-libs/mmtk/mmtk-2.7.9.ebuild
new file mode 100644
index 000000000000..311ce3d77515
--- /dev/null
+++ b/sci-libs/mmtk/mmtk-2.7.9.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+# This number identifies each release on the CRU website.
+# Can't figure out how to avoid hardcoding it.
+NUMBER="4324"
+
+MY_PN=${PN/mmtk/MMTK}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Molecular Modeling ToolKit for Python"
+HOMEPAGE="http://dirac.cnrs-orleans.fr/MMTK/"
+SRC_URI="http://sourcesup.cru.fr/frs/download.php/${NUMBER}/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="CeCILL-2"
+KEYWORDS="~amd64 ~x86 ~ppc ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	<dev-python/numpy-1.9[${PYTHON_USEDEP}]
+	dev-python/scientificpython[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}"/${MY_P}
+
+python_prepare_all() {
+	export MMTK_USE_CYTHON="1"
+	sed \
+		-e "/ext_package/d" \
+		-e "/^if sphinx/s|:| == 3:|g" \
+		-e "s:import sphinx:sphinx = None:g" \
+		-i "${S}"/setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	DOCS=( README* Doc/CHANGELOG )
+	HTML_DOCS=( Doc/HTML/. )
+
+	distutils-r1_python_install_all
+
+	if use examples; then
+		insinto /usr/share/${P}
+		doins -r Examples
+	fi
+}