sci-libs/scikit-image: add 0.19.3

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/sci-libs/scikit-image/scikit-image-0.19.3.ebuild b/sci-libs/scikit-image/scikit-image-0.19.3.ebuild
new file mode 100644
index 000000000000..870f5cb3d753
--- /dev/null
+++ b/sci-libs/scikit-image/scikit-image-0.19.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Image processing routines for SciPy"
+HOMEPAGE="https://scikit-image.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/imageio[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pywavelets[${PYTHON_USEDEP}]
+	dev-python/scipy[sparse(+),${PYTHON_USEDEP}]
+	dev-python/tifffile[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+
+DOCS=( CONTRIBUTORS.txt RELEASE.txt )
+
+distutils_enable_tests pytest
+# There is a programmable error in your configuration file:
+#distutils_enable_sphinx doc/source dev-python/numpydoc dev-python/myst_parser
+
+python_test() {
+	# This needs to be run in the install dir
+	cd "${WORKDIR}/${P}-${EPYTHON//./_}/install/usr/lib/${EPYTHON}/site-packages/skimage" || die
+	distutils-r1_python_test
+}
+
+pkg_postinst() {
+	optfeature "FITS io capability" dev-python/astropy
+	optfeature "GTK" dev-python/pygtk
+	optfeature "Parallel computation" dev-python/dask
+	optfeature "io plugin providing most standard formats" dev-python/imread
+	# not in portage yet
+	#optfeature "io plugin providing a wide variety of formats, including specialized formats using in medical imaging." dev-python/simpleitk
+}