sci-libs/shapelib: add 1.6.0, security bump

- Bump subslot (now installs as libshp.so.4)
- Tests pass
- Bump to EAPI 8
- Convert SRC_URI to HTTPS
- Convert econf args to array

Bug: https://bugs.gentoo.org/877605
Signed-off-by: Christopher Fore <csfore@posteo.net>
Closes: https://github.com/gentoo/gentoo/pull/36367
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/sci-libs/shapelib/shapelib-1.6.0.ebuild b/sci-libs/shapelib/shapelib-1.6.0.ebuild
new file mode 100644
index 000000000000..576d2163972f
--- /dev/null
+++ b/sci-libs/shapelib/shapelib-1.6.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Library for manipulating ESRI Shapefiles"
+HOMEPAGE="http://shapelib.maptools.org/"
+SRC_URI="https://download.osgeo.org/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0/4"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc static-libs"
+
+src_prepare() {
+	default
+	rm -f m4/* || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--includedir="${EPREFIX}"/usr/include/libshp
+		--prefix="${EPREFIX}"/usr
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	use doc && HTML_DOCS=( web/. )
+	default
+
+	if ! use static-libs; then
+		find "${ED}" \( -name '*.la' -o -name '*.a' \) -delete || die
+	fi
+}