sci-libs/cartopy: add 0.21.1

Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/sci-libs/cartopy/Manifest b/sci-libs/cartopy/Manifest
index 2a15d555af82..cf0c8bc01cbb 100644
--- a/sci-libs/cartopy/Manifest
+++ b/sci-libs/cartopy/Manifest
@@ -1 +1,2 @@
 DIST cartopy-0.21.0.gh.tar.gz 10815721 BLAKE2B 8a249d6e6b19d5a784a25d44fe062b5417811078f9b5362beed4e60f6a7e3d89996773a0b9530c96a27d3aa3a5a62ce05010ee17cc9ea71d33b9d7f6d1a5c602 SHA512 bb227e3f9ff591a33e7b4c053010321b04f2a03c68e84b1ea17cab125fc1d04f587b7f54125fe5bd3faae1379a0df8a217fd0ad5f85a7c461f9595f5b38f72f9
+DIST cartopy-0.21.1.gh.tar.gz 10815884 BLAKE2B 4137f593b6ce35270f9df5016529250a07c57ec5a95843db8740eb494f55109b5129cf72153b0216e4f786771bf5cedde3caaecd40175fe9ad5c6fb65ad84788 SHA512 de1d09ee3bf6af13bcc7cc4bb1f7c13335ba67e05d2ad64efa0fb00bdb74c7e13c6fc44822d5ac1d70ee7d39b2322280c1395dc66119b9ecd94ca26014e413a1
diff --git a/sci-libs/cartopy/cartopy-0.21.1.ebuild b/sci-libs/cartopy/cartopy-0.21.1.ebuild
new file mode 100644
index 000000000000..37196a73aff3
--- /dev/null
+++ b/sci-libs/cartopy/cartopy-0.21.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 multiprocessing virtualx
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python package for geospatial data processing and analysis"
+HOMEPAGE="https://scitools.org.uk/cartopy"
+SRC_URI="https://github.com/SciTools/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	sci-libs/gdal[python,${PYTHON_SINGLE_USEDEP}]
+	sci-libs/geos
+	$(python_gen_cond_dep '
+		>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+		dev-python/pyproj[${PYTHON_USEDEP}]
+		sci-libs/pyshp[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools_scm_git_archive[${PYTHON_USEDEP}]
+		dev-python/cython[${PYTHON_USEDEP}]
+	')
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/filelock[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/flufl-lock[${PYTHON_USEDEP}]
+			dev-python/pytest-mpl[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Require network access, not covered by markers
+	lib/cartopy/tests/mpl/test_crs.py
+	lib/cartopy/tests/mpl/test_gridliner.py
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+	# Prepare matplotlib backend for test suite
+	export MPLCONFIGDIR="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+
+	# Drop all tests needing network access
+	virtx epytest -n "$(makeopts_jobs)" -m "not network and not natural_earth" || die "test failed"
+}