proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 74 insertions, 0 deletions

diff --git a/sci-mathematics/cgal/cgal-4.3.ebuild b/sci-mathematics/cgal/cgal-4.3.ebuild
new file mode 100644
index 000000000000..46bbca202239
--- /dev/null
+++ b/sci-mathematics/cgal/cgal-4.3.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+CMAKE_BUILD_TYPE=Release
+
+inherit multilib cmake-utils
+
+MY_P=CGAL-${PV}
+PID=32995
+DPID=33000
+
+DESCRIPTION="C++ library for geometric algorithms and data structures"
+HOMEPAGE="http://www.cgal.org/ https://gforge.inria.fr/projects/cgal/"
+SRC_URI="
+	http://gforge.inria.fr/frs/download.php/${PID}/${MY_P}.tar.xz
+	doc? ( http://gforge.inria.fr/frs/download.php/${DPID}/${MY_P}-doc_html.tar.xz )"
+
+LICENSE="LGPL-3 GPL-3 Boost-1.0"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples +gmp mpfi qt4"
+
+RDEPEND="
+	dev-libs/boost
+	dev-libs/mpfr:0
+	sys-libs/zlib
+	x11-libs/libX11
+	virtual/glu
+	virtual/opengl
+	gmp? ( dev-libs/gmp[cxx] )
+	qt4? (
+		dev-qt/qtgui:4
+		dev-qt/qtopengl:4
+	)
+	mpfi? ( sci-libs/mpfi )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS="AUTHORS CHANGES* README"
+
+src_prepare() {
+	cmake-utils_src_prepare
+	sed \
+		-e '/install(FILES AUTHORS/d' \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs+=(
+		-DCGAL_INSTALL_LIB_DIR=$(get_libdir)
+		-DWITH_CGAL_Qt3=OFF
+		-DWITH_LEDA=OFF
+		$(cmake-utils_use_with gmp)
+		$(cmake-utils_use_with gmp GMPXX)
+		$(cmake-utils_use_with qt4 CGAL_Qt4)
+		$(cmake-utils_use_with mpfi)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${WORKDIR}"/doc_html/. )
+	cmake-utils_src_install
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples demo
+	fi
+}