sci-mathematics/coq-serapi: bump to 0.19.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

3 files changed, 88 insertions, 0 deletions

diff --git a/sci-mathematics/coq-serapi/Manifest b/sci-mathematics/coq-serapi/Manifest
index 31b560b4f01e..9329b3bb17ba 100644
--- a/sci-mathematics/coq-serapi/Manifest
+++ b/sci-mathematics/coq-serapi/Manifest
@@ -1 +1,2 @@
 DIST coq-serapi-0.18.1.tar.gz 275040 BLAKE2B 9224505da004ff54c3d21c394e6049b5e15b91c3531cd0d80aae89ee6ce9e92bb626a43fdef8fad58fea4d017b3ed3f13d5d1735e7cfc1ae3bcebed2c70ce332 SHA512 a8eca10734a5b1aa5c6a890998f18d673050ca1e975b5e88643176bfd627b4c0d05cf0be1b75ccfd155b9e74f357ee61bf8225fd144b6a624a3bdd359396428c
+DIST coq-serapi-0.19.0.tar.gz 180779 BLAKE2B 27083a851139e983158b4cb251d37971d0eec61dd91303a0d09512e690c56a75624dab8c5120eebaed1e7bb168d0b2b889d538854812506c4d0a804f7bee7423 SHA512 e01706beb957315011682f2f74448e66c7a8a077418eeaf7d3fa21414bdf88950b75adbfe2392656e4d6036ce6585d4d53b1dadfd8379249b2943ea389c9c83e
diff --git a/sci-mathematics/coq-serapi/coq-serapi-0.19.0.ebuild b/sci-mathematics/coq-serapi/coq-serapi-0.19.0.ebuild
new file mode 100644
index 000000000000..ed213e2d76e6
--- /dev/null
+++ b/sci-mathematics/coq-serapi/coq-serapi-0.19.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COQ_MIN_V=8.19.0
+COQ_MAX_V=8.20.0
+
+inherit dune elisp-common
+
+DESCRIPTION="Serialization library and protocol for interaction with the Coq proof assistant"
+HOMEPAGE="https://github.com/ejgallego/coq-serapi/"
+
+# The tarball in SRC_URI is comprised of <supported coq>+<package version>
+SRC_URI="https://github.com/ejgallego/${PN}/archive/${COQ_MIN_V}+${PV}.tar.gz
+	-> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COQ_MIN_V}-${PV}"
+
+LICENSE="GPL-3+"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="emacs +ocamlopt test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=sci-mathematics/coq-${COQ_MIN_V}:= <sci-mathematics/coq-${COQ_MAX_V}:=
+	>=dev-ml/ppx_sexp_conv-0.13.0:=
+	dev-ml/cmdliner:=
+	dev-ml/ppx_compare:=
+	dev-ml/ppx_deriving:=
+	dev-ml/ppx_deriving_yojson:=
+	dev-ml/ppx_hash:=
+	dev-ml/ppx_import:=
+	dev-ml/sexplib:=
+	dev-ml/yojson:=
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	emacs? (
+		>=app-editors/emacs-23.1:*
+	)
+	test? (
+		sci-mathematics/coq-mathcomp
+	)
+"
+
+PATCHES=( "${FILESDIR}/${PN}-0.19.0-sertop-el.patch" )
+
+SITEFILE="50sertop-gentoo.el"
+
+src_compile() {
+	dune_src_compile
+
+	use emacs && elisp-compile sertop/*.el
+}
+
+src_install() {
+	dune_src_install
+
+	rm -r "${ED}/usr/share/emacs" || die
+
+	if use emacs ; then
+		elisp-install "${PN}" sertop/*.el{,c}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/sci-mathematics/coq-serapi/files/coq-serapi-0.19.0-sertop-el.patch b/sci-mathematics/coq-serapi/files/coq-serapi-0.19.0-sertop-el.patch
new file mode 100644
index 000000000000..b6aa6c1784ca
--- /dev/null
+++ b/sci-mathematics/coq-serapi/files/coq-serapi-0.19.0-sertop-el.patch
@@ -0,0 +1,11 @@
+--- a/sertop/sertop.el
++++ b/sertop/sertop.el
+@@ -37,7 +37,7 @@
+                            (buffer-file-name))))
+ 
+ (defvar sertop-executable-path
+-  (or (expand-file-name "sertop.native" sertop--root)
++  (or (executable-find "sertop.native")
+       (executable-find "sertop"))
+   "Path to sertop.")
+